[gentoo-commits] repo/gentoo:master commit in: mail-filter/imapfilter/

["Sam James" <sam@gentoo.org>]

commit:     0e1e8ba45af1913742d440c63efde2390eca9e2c
Author:     Holger Hoffstätte <holger <AT> applied-asynchrony <DOT> com>
AuthorDate: Sun Jun 26 19:18:57 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jun 28 09:31:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0e1e8ba4

mail-filter/imapfilter: add 5.4 & luajit to LUA_COMPAT, correctly depend on libpcre2

Closes: https://bugs.gentoo.org/828110
Closes: https://bugs.gentoo.org/854471
Signed-off-by: Holger Hoffstätte <holger <AT> applied-asynchrony.com>
Closes: https://github.com/gentoo/gentoo/pull/26082
Signed-off-by: Sam James <sam <AT> gentoo.org>

 mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild | 48 +++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild b/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild
new file mode 100644
index 000000000000..6f25c2f85bc8
--- /dev/null
+++ b/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua-single toolchain-funcs
+
+DESCRIPTION="An IMAP mail filtering utility"
+HOMEPAGE="https://github.com/lefcha/imapfilter"
+SRC_URI="https://github.com/lefcha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	dev-libs/libpcre2
+	${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS NEWS README samples/*"
+
+src_prepare() {
+	default
+	sed -i -e "/^PREFIX/s:/usr/local:${EPREFIX}/usr:" \
+		-e "/^MANDIR/s:man:share/man:" \
+		-e "/^CFLAGS/s:CFLAGS =:CFLAGS +=:" \
+		-e "/^CFLAGS/s/-O//" \
+		src/Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		LDFLAGS="${LDFLAGS}" \
+		INCDIRS=$(lua_get_CFLAGS) \
+		LIBLUA=$(lua_get_LIBS)
+}
+
+src_install() {
+	default
+	doman doc/imapfilter.1 doc/imapfilter_config.5
+}