[gentoo-commits] repo/gentoo:master commit in: app-admin/vault/

["Zac Medico" <zmedico@gentoo.org>]

commit:     44dd75cd6bd83a9d477bbdc9117888c29f0c47ea
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 16:43:11 2022 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 16:43:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44dd75cd

app-admin/vault: add 1.11.0

Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-admin/vault/Manifest            |  2 +
 app-admin/vault/vault-1.11.0.ebuild | 86 +++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index 32655b432ae0..0ba6bcfe0fab 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -2,3 +2,5 @@ DIST vault-1.10.3-vendor.tar.gz 48109465 BLAKE2B 45985a6ae4445ec75b29f198113fdd1
 DIST vault-1.10.3-webui.tar.xz 1258176 BLAKE2B 85fd1b804b880a3dcdbbd4e825b663f02a985259d0a74ab7cddf4a9a2393c60918b389d0e4e81574b93c8b0867647fc1d17f7ca3e719b36ab41d6825adfbdaae SHA512 9640a7e25de0761a310e234098a0dd31db9e04b30036045ff7edaaca8f7496466f1c0148855a5e1ef270638e90a8fb97aff2c5482b32512772021c99691a5aa5
 DIST vault-1.10.4-vendor.tar.gz 50089463 BLAKE2B 299e7619f158a2ea0683feaaff4a7c5019da02fa03daf25e0b4415f03b703ca11733c486165a21ffcd5b3c1d221db5b9e24e898f3cf3de014c09e29531841dcf SHA512 056a6056bac127083358f1811e8e587f0521b734219a6e03e019527fafcadfbd0d71a05314cb269e27b03423349b5a857d234d3949d0d15e7c7b1175bc573c57
 DIST vault-1.10.4-webui.tar.xz 1258340 BLAKE2B 556da0e566852e5c6a091bd9139a88a9099e5f6422e225b7a4068e1bef3d9fd5a2292bb2efbe12545c20f6c956fd6180500972d5248f05bbb96db50a90ae4741 SHA512 ec9cc568d8d56ba379d0fdee31e0edc8aa8110366b112790573794975a0b32324f517e5fead39fbf59ab99667837b0e08ebadfb6d41dcde85d474712b34b475a
+DIST vault-1.11.0-vendor.tar.gz 49927497 BLAKE2B d7a12c1c1710c2a487b9c08a871b1d7b011d90957cab6980eb2f7eaff4ff544509899ee07c326bba8310ff16ee3bf88586dba340249cf0f7804007963af7d692 SHA512 b3b9275d5ae41c21826ed0bf1eeaffffe10e5e95b085bf8cf6af6c9ff565848f4a3f83d9a8d6165867de11b0f877383cb972e7d4313a753b0dca391203ecb4c6
+DIST vault-1.11.0-webui.tar.xz 1335764 BLAKE2B 9733ae0c2fe04018dac73358a56a162e23877e68b3ce59ca569cea7e27f39c91727ab0810a737167b3f02d92a0d58e9a7195da892c677bece60fbe965dba7fdf SHA512 a5df9f0e854af8f30d6b5d15628a087c1c37361e2a0de4e412e7f78ac51affc774c1a6ed084dd849b68b147d527547593c1124d1170be38b918efd28081a6f0b

diff --git a/app-admin/vault/vault-1.11.0.ebuild b/app-admin/vault/vault-1.11.0.ebuild
new file mode 100644
index 000000000000..004b6dd49b57
--- /dev/null
+++ b/app-admin/vault/vault-1.11.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps go-module systemd
+
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+SRC_URI="https://github.com/zmedico/vault/archive/refs/tags/v${PV}-vendor.tar.gz -> ${P}-vendor.tar.gz
+	webui? (
+		https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+webui"
+
+BDEPEND="
+	app-arch/zip
+	dev-go/gox
+	>=dev-lang/go-1.15.3"
+COMMON_DEPEND="acct-group/vault
+	acct-user/vault"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+RESTRICT+=" test"
+S=${WORKDIR}/${P}-vendor
+
+src_unpack() {
+	default
+}
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-e "s|^BUILD_DATE=.*|BUILD_DATE=$(date +%Y-%m-%dT%H:%M:%SZ)|" \
+		-i scripts/build.sh || die
+	sed -e "/hooks/d" \
+		-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+		-e "s/gofumpt/gofmt/g" \
+		-i Makefile || die
+	if [[ -d "${WORKDIR}/http/web_ui" ]]; then
+		rm -rf "${S}/http/web_ui" || die
+		mv "${WORKDIR}/http/web_ui" "${S}/http/web_ui" ||
+			die "mv failed"
+	else
+		mkdir -p "${S}/http/web_ui" || die
+		touch "${S}/http/web_ui/no_web_ui" || die
+	fi
+}
+
+src_compile() {
+	mkdir "${T}"/bin || die
+	BUILD_TAGS="$(usex webui ui '')" \
+	GOPATH="${T}" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake bin
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}