[gentoo-commits] repo/gentoo:master commit in: app-crypt/libu2f-host/

["Marek Szuba" <marecki@gentoo.org>]

commit:     bc00377ad62649ab9ad00c42a3c00562b7b82e8f
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 09:55:59 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 10:07:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bc00377a

app-crypt/libu2f-host: call udev_reload

Also bump EAPI to 8.

Closes: https://bugs.gentoo.org/854246
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-crypt/libu2f-host/libu2f-host-1.1.10-r1.ebuild | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/app-crypt/libu2f-host/libu2f-host-1.1.10-r1.ebuild b/app-crypt/libu2f-host/libu2f-host-1.1.10-r1.ebuild
new file mode 100644
index 000000000000..c49ed0d65a11
--- /dev/null
+++ b/app-crypt/libu2f-host/libu2f-host-1.1.10-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info udev
+
+DESCRIPTION="Yubico Universal 2nd Factor (U2F) Host C Library"
+HOMEPAGE="https://developers.yubico.com/libu2f-host/"
+SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.xz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="systemd"
+
+DEPEND="dev-libs/hidapi
+	dev-libs/json-c:="
+# The U2F device node will be owned by group 'plugdev'
+# in non-systemd configurations
+RDEPEND="${DEPEND}
+	!systemd? ( acct-group/plugdev )
+	systemd? ( sys-apps/systemd[acl] )"
+BDEPEND="virtual/pkgconfig"
+
+CONFIG_CHECK="~HIDRAW"
+
+PATCHES=( "${FILESDIR}/${P}-json-boolean.patch" )
+
+src_install() {
+	default
+	if use kernel_linux; then
+		udev_dorules 70-u2f.rules
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	udev_reload
+
+	if ! use systemd; then
+		elog "Users must be a member of the 'plugdev' group"
+		elog "to be able to access U2F devices"
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}