[gentoo-commits] repo/gentoo:master commit in: dev-util/redo/

["Sam James" <sam@gentoo.org>]

commit:     9d41061cf0a2f1f85399bc1442098bb97fe96386
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 23 05:34:22 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jun 23 05:34:57 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d41061c

dev-util/redo: add 0.42d

Bug: https://bugs.gentoo.org/775212
Bug: https://bugs.gentoo.org/671840
Closes: https://bugs.gentoo.org/832245
Closes: https://bugs.gentoo.org/764068
Closes: https://bugs.gentoo.org/671842
Closes: https://bugs.gentoo.org/678988
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/redo/Manifest          |  1 +
 dev-util/redo/redo-0.42d.ebuild | 63 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-util/redo/Manifest b/dev-util/redo/Manifest
index 3f16c673454c..dc0b3f604565 100644
--- a/dev-util/redo/Manifest
+++ b/dev-util/redo/Manifest
@@ -1 +1,2 @@
 DIST redo-0.42c.tar.gz 195232 BLAKE2B b24969d71b247d02642340cebbf325e2ae68d4893d02e489930120e6aac76bd3099fd42e7dc36dae1fdea5c7825657957291876b906c2671a6319f8eb45a9d91 SHA512 3196ff5941d9e62084c7332a6771edd0db0082a499ba16fb6de273295c65b734e7dadb29a9fca3e6266421bc964369a8e725ef55f59ade2ecfb5e8bcc446ced0
+DIST redo-0.42d.tar.gz 195186 BLAKE2B 2f36dc8380d9e20475788b8d94ce02d6375ddf0a0e745dc68b7e350c427522088243bca16bd8d7c760ada17de75560e9cfdf5282a5e39081fee395a142164c82 SHA512 2749a1a1046f8edd63c4b4e2b0f4d95988dfcf8c776b264007914e583fc21ff51447be34ffc2c136c343ace8c38147d6a43c0c0dd01a681b6283a38d5d8f3fb7

diff --git a/dev-util/redo/redo-0.42d.ebuild b/dev-util/redo/redo-0.42d.ebuild
new file mode 100644
index 000000000000..3eb879fff843
--- /dev/null
+++ b/dev-util/redo/redo-0.42d.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2018-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="sqlite"
+inherit edo multiprocessing python-single-r1
+
+DESCRIPTION="Smaller, easier, more powerful, and more reliable than make"
+HOMEPAGE="https://github.com/apenwarr/redo"
+SRC_URI="https://github.com/apenwarr/redo/archive/${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${P}
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/markdown[${PYTHON_USEDEP}]
+	')
+	${PYTHON_DEPS}
+"
+RDEPEND="${BDEPEND}"
+
+src_prepare() {
+	default
+
+	sed -i -e "s:which:command -v:" redo/sh.do || die
+	sed -i "1s;^;#!${PYTHON}\n;" docs/md2man.py || die
+}
+
+src_configure() {
+	echo ${PYTHON} > redo/whichpython || die
+}
+
+src_compile() {
+	edo ./do -j$(makeopts_jobs) build
+}
+
+src_test() {
+	local ARCH= CFLAGS= CXXFLAGS= LDFLAGS=
+	edo ./do -j$(makeopts_jobs) test
+}
+
+src_install() {
+	DESTDIR="${D}" \
+	DOCDIR="${D}/usr/share/doc/${PF}" \
+	LIBDIR="${D}/$(python_get_sitedir)/${PN}" \
+	edo ./do -j$(makeopts_jobs) \
+		install
+
+	python_fix_shebang "${D}"
+
+	sed -i \
+		-e 's|/lib/|/'"$(get_libdir)"'/|g' \
+		"${D}"/usr/bin/* || die
+
+	python_optimize
+}