[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Sam James" <sam@gentoo.org>]

commit:     7fce0754cd9accc66910fd3fba92b5c1af6dccc7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 22 02:16:26 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Jun 22 02:16:26 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7fce0754

www-client/opera-beta: automated bump (89.0.4447.20)

Signed-off-by: Sam James <sam <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 +
 .../opera-beta/opera-beta-89.0.4447.20.ebuild      | 158 +++++++++++++++++++++
 2 files changed, 159 insertions(+)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 38d7f3240981..ec3b0b23f75a 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,5 @@
 DIST opera-beta_88.0.4412.18_amd64.deb 84660352 BLAKE2B 00bca30e13c5d1a058afc27ba72e31b47a9afab0cecf13e375ec12f334467872cb5d6f44d6a2fe9eb3dc56c0a59f2d590be6cdc88adeba840dc83381baeb76ae SHA512 843e299dd65ce4cc80130968121b87d099a020856a3329b81e2eabf795ce8b2402147d138df76dd9577ec83fbb5f2b0d9de778f38993339497fec83a81cf3ba1
 DIST opera-beta_88.0.4412.20_amd64.deb 84683044 BLAKE2B 79f5961a441008ba0e28164c7f5673565cf2ca78e96a4c0e6674414ab92c743c4178dba770dfc681dc7675028730adf5eb517a2958316a422725754dd9a5dfdd SHA512 84ec4bd4ccfcb80644b80e1722153283eccf7e67f42666021f66ad72fcb52ce53ee2805fd754b936660402fd0f9d1c0b9c4920182399eab83b46fc350cf0920c
 DIST opera-beta_89.0.4447.12_amd64.deb 86320096 BLAKE2B 993f12fc5cb5b26ea3f2351435735114fa6c28a7ec0c15c19abfe74aadf9e81df00b868bcc42a3adebe9125e98b3441d48a1428062c00f740cc7c2eec4a9ae9d SHA512 a8818f6de4397675b6995c771b3160c910e4a947f3b928d49349fc64d12d1f9a8dfb4b6f4798616d76f133e12fe0425821631a91382cadab91ef9e30a2e76f34
+DIST opera-beta_89.0.4447.20_amd64.deb 86875548 BLAKE2B 4e6376c45e5378a8b6a3c6fdad0dac34040fd79ecaef55d88a2f34bd165a282ff99c8bfc83bf2f072502340a2bbfb641e086412f0dfbba311b99bc797a7d3401 SHA512 7f6165e5106f0eb9b231889cb2ce883a09266dad8883f86810ac843faa83942be1f9f10e9c64b6489c3b88fb16d78283309bb121359a400911de9b316b754c05
 DIST opera-ffmpeg-codecs-102.0.5005.61.tar.xz 1429920 BLAKE2B a4cb07805650c3cd7f7e1127e475775c95d74b8cd17af5ad736a6d4f256176586b1608c2a617961cf2f3f7980879bc8f1a84cd9faa4838eafbc7b1b4e2edfe1a SHA512 af20383a0b77da89bf2ef52b412d9cce0a1f12bcfe2612ebd5110f1e8008cfff874da36e00b980609ac29346c545f2326bbe5f1b42473530f2886d67a00f52ca

diff --git a/www-client/opera-beta/opera-beta-89.0.4447.20.ebuild b/www-client/opera-beta/opera-beta-89.0.4447.20.ebuild
new file mode 100644
index 000000000000..d9356701daff
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-89.0.4447.20.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="102.0.5005.61"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}