[gentoo-commits] repo/gentoo:master commit in: dev-python/graph-tool/

["David Seifert" <soap@gentoo.org>]

commit:     71977dc201baa372df22f87afe9b332a586f52c0
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 19 14:14:07 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Jun 19 14:14:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=71977dc2

dev-python/graph-tool: add 2.45

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.45.ebuild | 84 ++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 48975bee706b..1bf7d9244918 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.44.tar.bz2 15149379 BLAKE2B d15413f4e8642b96f62d88631c216e600e24aa878b08a173f1a00f1700aa3c6f4b1b3f806956b811b209a2d42ec1178e2488946d96f056f528a046cbd6cc330a SHA512 b90dc541ec77f89fdbb64697ec5e200d9c7c4ec4b8849c75d008b83dab8f54c95bd230f5d72e32d656f86a201ab66eee25aa774b7983355f7af9304b52527e40
+DIST graph-tool-2.45.tar.bz2 15156784 BLAKE2B b9086e5545ace668f703bf06363a382fab734a63d5684d44b62407a06a0464df6a4a9c8c7ccd26e53118c1d24469ed2eb4670939dc0889fafe2f73a2c176101b SHA512 46a4a3a22033c74c69e0ba5ce8f0856d2f35934d52850ef4a542384c8fd327daf56341675a3299a8db87d4a227b5583f0564f8917ecf28081cb1dd4091563490

diff --git a/dev-python/graph-tool/graph-tool-2.45.ebuild b/dev-python/graph-tool/graph-tool-2.45.ebuild
new file mode 100644
index 000000000000..f45d24d4fbfe
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.45.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/boost-1.70:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}