[gentoo-commits] repo/proj/guru:dev commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac.paragon@gmail.com>]

commit:     4f1ac2fa4d90686b213355464566738e5928e998
Author:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
AuthorDate: Sun Jun 19 05:51:04 2022 +0000
Commit:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
CommitDate: Sun Jun 19 05:51:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=4f1ac2fa

app-misc/fastfetch: add 1.5.4

Signed-off-by: Viorel Munteanu <ceamac.paragon <AT> gmail.com>

 app-misc/fastfetch/Manifest               |  1 +
 app-misc/fastfetch/fastfetch-1.5.4.ebuild | 75 +++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 20d9eb09e..47ab99f88 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1 +1,2 @@
 DIST fastfetch-1.5.3.tar.gz 345268 BLAKE2B 98c385d345bc2947f0301175269c72b61c6858f553b581705be1d81479355b6140a5cf2fb0dacd988ed7726d5079d5d26f7438223acddf22c9b2a4a1b39bdf09 SHA512 4f3656189f90141c3b9c26f75afee1ae9aa658058d54f00d8cb1a2a33baa17578d3847dfdcf1732fb35abd3391911954651f5af13049bb63a8940b65b007ca28
+DIST fastfetch-1.5.4.tar.gz 345879 BLAKE2B fac422642e6d2af4658d8f7c23c83b3c15a485eda8705626eda9eba024a4714b814e654f688015932cef3b80332c9e6ea5308d371848719786daca4e73ae059e SHA512 20a305235018ddb1af911246222c7f625311abaf95aa3feed6d7dc06e98b974453f80c34933e286709c721a48238d06b532f2770e72cb3f4018ad54de399a084

diff --git a/app-misc/fastfetch/fastfetch-1.5.4.ebuild b/app-misc/fastfetch/fastfetch-1.5.4.ebuild
new file mode 100644
index 000000000..5a9974833
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.5.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=$(use imagemagick && has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_IMAGEMAGICK6=$(use imagemagick && has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+	)
+
+	cmake_src_configure
+}