[gentoo-commits] repo/gentoo:master commit in: sys-libs/libapparmor/

["Sam James" <sam@gentoo.org>]

commit:     ee7cb639713d630628cc5d538a6df91e2b299df3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 12 15:39:10 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jun 12 15:56:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee7cb639

sys-libs/libapparmor: fix distutils-r1 usage

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-libs/libapparmor/libapparmor-3.0.3-r1.ebuild | 103 +++++++++++++++++++++++
 1 file changed, 103 insertions(+)

diff --git a/sys-libs/libapparmor/libapparmor-3.0.3-r1.ebuild b/sys-libs/libapparmor/libapparmor-3.0.3-r1.ebuild
new file mode 100644
index 000000000000..9b57936f1568
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-3.0.3-r1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python3_{8..10} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools distutils-r1 perl-functions
+
+MY_PV="$(ver_cut 1-2)"
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
+SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc +perl +python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/autoconf-archive
+	sys-devel/bison
+	sys-devel/flex
+	doc? ( dev-lang/perl )
+	perl? ( dev-lang/swig )
+	python? ( dev-lang/swig	)"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+# depends on the package already being installed
+#RESTRICT="test"
+
+src_prepare() {
+	rm -r m4 || die "failed to remove bundled macros"
+
+	default
+	eautoreconf
+
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with perl) \
+		$(use_with python)
+}
+
+src_compile() {
+	emake -C src
+	emake -C include
+	use doc && emake -C doc
+	use perl && emake -C swig/perl
+
+	if use python ; then
+		pushd swig/python > /dev/null || die
+		emake libapparmor_wrap.c
+		distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" -C src install
+	emake DESTDIR="${D}" -C include install
+	use doc && emake DESTDIR="${D}" -C doc install
+
+	if use perl ; then
+		emake DESTDIR="${D}" -C swig/perl install
+		perl_set_version
+		insinto "${VENDOR_ARCH}"
+		doins swig/perl/LibAppArmor.pm
+
+		# bug 620886
+		perl_delete_localpod
+		perl_fix_packlist
+	fi
+
+	if use python ; then
+		pushd swig/python > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	python_moduleinto LibAppArmor
+	python_domodule LibAppArmor.py
+}