[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-pep517/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3587508fdbe3e37263d8f1b046d64cb49235ef99
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  8 19:36:10 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun  8 19:40:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3587508f

dev-python/pdm-pep517: Bump to 0.12.7

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-pep517/Manifest                 |  1 +
 dev-python/pdm-pep517/pdm-pep517-0.12.7.ebuild | 58 ++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index d961118cf2a7..bfda15846669 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-pep517-0.12.4.gh.tar.gz 304353 BLAKE2B ca2b18af38423f7430a40e5cced207bd4bec8d101204902c89f335c5d08131e95fe17c5af7a3ef0e654c9e2106145ef5242c9015924a2711c90dbb0d2f48128e SHA512 2007a84909147cd48e9ea6114119a63855ddf48e220f8c896d516b6bddd5a7bd62046f090d739a5069b9e06700f0318e57bd1a4b3c7531508b41540357639c5e
 DIST pdm-pep517-0.12.5.gh.tar.gz 304900 BLAKE2B 0e2b6b126226be4b462a254baedfd689d21250e4cdaf80bc8372a1742c795fc4fc0f4f0c891b5d2546320957223d2be65cd9881ab8a190fc1e928b42ec450990 SHA512 00ab751c69a575c4a51afd39e47265b1a593666649d7b70177c8ce6047c1761b00e3fb2338654a7bbd48063d1f32d03fd59aa3c5e8c82393e23eb797f706c574
+DIST pdm-pep517-0.12.7.gh.tar.gz 304959 BLAKE2B 0571a77803b999f88f38da843c5fcf126eeb538c6812c3e245be2fc14d6cd19929559985efba2d245bbf0efb00e412b2133fca6bbe9e63317e6b7311867e0072 SHA512 45da8ab31071a57062fac5b89abe7d912d787d647eda1b45fe3941c43687fe0fe5c8d11e539290035375e17eef808489000513e3128708fcefd851e792757b8f

diff --git a/dev-python/pdm-pep517/pdm-pep517-0.12.7.ebuild b/dev-python/pdm-pep517/pdm-pep517-0.12.7.ebuild
new file mode 100644
index 000000000000..ce38d4f05e82
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-0.12.7.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}