[gentoo-commits] repo/proj/guru:dev commit in: gui-apps/fuzzel/

["Jonas Frei" <freijon@pm.me>]

commit:     7b9b09b1ff598f9cc693ea20c28ddb58db27723b
Author:     Jonas Frei <freijon <AT> pm <DOT> me>
AuthorDate: Fri Jun  3 04:44:27 2022 +0000
Commit:     Jonas Frei <freijon <AT> pm <DOT> me>
CommitDate: Fri Jun  3 04:44:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=7b9b09b1

gui-apps/fuzzel: initial import

Signed-off-by: Jonas Frei <freijon <AT> pm.me>

 gui-apps/fuzzel/Manifest            |  1 +
 gui-apps/fuzzel/fuzzel-1.7.0.ebuild | 54 +++++++++++++++++++++++++++++++++++++
 gui-apps/fuzzel/fuzzel-9999.ebuild  | 54 +++++++++++++++++++++++++++++++++++++
 gui-apps/fuzzel/metadata.xml        | 17 ++++++++++++
 4 files changed, 126 insertions(+)

diff --git a/gui-apps/fuzzel/Manifest b/gui-apps/fuzzel/Manifest
new file mode 100644
index 000000000..405e81c85
--- /dev/null
+++ b/gui-apps/fuzzel/Manifest
@@ -0,0 +1 @@
+DIST fuzzel-1.7.0.tar.gz 399615 BLAKE2B 73f3eac98660f5325d1a6547ebc64c473b62b5f70a25ff12166e4592cb08b1d3c415107b65ef639e8500a0011232047acf214d6501aa5714cbc83c46d73c6e20 SHA512 a1c1f97c5964e0afb6ae449d8d2a06635b12719445e3a5f139fa592fa773bf7f9592cdeb2eb81054356831793e91a3c5eb6677b93092982eff346a7fb9078b4e

diff --git a/gui-apps/fuzzel/fuzzel-1.7.0.ebuild b/gui-apps/fuzzel/fuzzel-1.7.0.ebuild
new file mode 100644
index 000000000..dd841f9f5
--- /dev/null
+++ b/gui-apps/fuzzel/fuzzel-1.7.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="cairo png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	cairo? ( x11-libs/cairo )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dwerror=false
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg librsvg none)
+		$(meson_feature cairo enable-cairo)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}

diff --git a/gui-apps/fuzzel/fuzzel-9999.ebuild b/gui-apps/fuzzel/fuzzel-9999.ebuild
new file mode 100644
index 000000000..dd841f9f5
--- /dev/null
+++ b/gui-apps/fuzzel/fuzzel-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="cairo png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	cairo? ( x11-libs/cairo )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dwerror=false
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg librsvg none)
+		$(meson_feature cairo enable-cairo)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}

diff --git a/gui-apps/fuzzel/metadata.xml b/gui-apps/fuzzel/metadata.xml
new file mode 100644
index 000000000..1f4dc9478
--- /dev/null
+++ b/gui-apps/fuzzel/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Jonas Frei</name>
+		<email>freijon@pm.me</email>
+	</maintainer>
+	<!--<upstream>
+		<remote-id type="codeberg">dnkl/fuzzel</remote-id>
+		<bugs-to>https://codeberg.org/dnkl/fuzzel/issues</bugs-to>
+	</upstream>-->
+	<use>
+		<flag name="cairo">Required for rounded corners and SVG icons</flag>
+		<flag name="png">Enable support for PNG icons</flag>
+		<flag name="svg">enables support for SVG icons</flag>
+	</use>
+</pkgmetadata>