[gentoo-commits] repo/gentoo:master commit in: app-text/xiphos/

["Marek Szuba" <marecki@gentoo.org>]

commit:     e53ce62d98b7c4033da6850b3f62fc5a371825a5
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun May 29 09:22:34 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun May 29 22:07:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e53ce62d

app-text/xiphos: disable the editor

The editor still requires either WebKit1 or GtkHTML, and upstream hasn't
made much progress on this in recent years (yes, years). Many other
distros have had the editor disabled for quite a while now (many thanks
to Debian for the patch we now use) and since upstream activity implies
they will make the editor officially optional soon, let's do the same.

Once this version has been stabilised we will finally be able to get rid
of gnome-extra/gtkhtml.

Bug: https://bugs.gentoo.org/667914
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-text/xiphos/Manifest               |  1 +
 app-text/xiphos/xiphos-4.2.1-r1.ebuild | 72 ++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/app-text/xiphos/Manifest b/app-text/xiphos/Manifest
index 739b78fae71c..fb4e42013ccf 100644
--- a/app-text/xiphos/Manifest
+++ b/app-text/xiphos/Manifest
@@ -1 +1,2 @@
+DIST xiphos-4.2.1-disable_webkit_editor.patch.xz 7432 BLAKE2B b1dd9db675a34433f4979247d57936920e178cf83cbcfa0fc2a4b9491855d064ecccdb8805a5615b9c91490c3ff2c24f7d951dad009e83952e5d6aa28c8a0730 SHA512 ae0d9b526143445529fa467bdd1b90015812a5d81396619e64a701962a608413c5875c137970d2b70dbac28085e7f40dc6049d591efaf96df7ddfb2cc64854da
 DIST xiphos-4.2.1.tar.xz 21586484 BLAKE2B 7529f770766dfc5bae6cb04bfeb3d3cc0714c4ebbd2282aca549e50b8a9ca4c74cdb8cb69667f1036ee33ee1c5d90e562cff80d520ce72651736e1f5f4274ba1 SHA512 624bd2e931c15e1665724918e756706f048e824dc13c2f1d5a05c32a93697137e75012564a14b7d2d0aa90c6a109c52ead51901e657d35a457ccf5f42204a0fe

diff --git a/app-text/xiphos/xiphos-4.2.1-r1.ebuild b/app-text/xiphos/xiphos-4.2.1-r1.ebuild
new file mode 100644
index 000000000000..599d16c4ff3f
--- /dev/null
+++ b/app-text/xiphos/xiphos-4.2.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="A Gtk+-based Bible-study frontend for SWORD"
+HOMEPAGE="https://xiphos.org/"
+SRC_URI="https://github.com/crosswire/${PN}/releases/download/${PV}/${P}.tar.xz
+	https://dev.gentoo.org/~marecki/dists/${CATEGORY}/${PN}/${PN}-4.2.1-disable_webkit_editor.patch.xz"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2 MIT MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dbus debug"
+
+COMMON="sys-apps/util-linux
+	dev-libs/libxml2
+	dev-libs/libxslt
+	dbus? ( dev-libs/dbus-glib )"
+RDEPEND="${COMMON}
+	>=app-text/sword-1.8.1
+	dev-libs/glib:2
+	dev-libs/icu
+	>=net-libs/biblesync-1.2.0
+	net-libs/webkit-gtk:4
+	sys-libs/zlib[minizip]
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}"
+BDEPEND="${COMMON}
+	app-arch/zip
+	app-text/yelp-tools
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	dev-util/glib-utils
+	dev-util/itstool
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}"/${PN}-4.2.1-disable_webkit_editor.patch
+	"${FILESDIR}"/${PN}-4.2.1-appdata_metainfo.patch
+	"${FILESDIR}"/${PN}-4.2.1-glib_version_min_required.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DDBUS=$(usex dbus)
+		-DDEBUG=$(usex debug)
+		-DPOSTINST=off
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if [[ -n "${REPLACING_VERSIONS}" ]]; then
+		local rver
+		for rver in ${REPLACING_VERSIONS}; do
+			if ver_test "${rver}" -le "4.2.1"; then
+				ewarn "Please note that ${PN} no longer provides an editor due to its dependency on outdated libraries."
+				ewarn "Studypad and the personal commentary will no longer work."
+				break
+			fi
+		done
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}