[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     db18e4473b59b11ad0ae8b38a71289d18ee7f51a
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri May 27 20:19:27 2022 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri May 27 20:19:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=db18e447

gnome-extra/gnome-calculator: add 42.1

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator/gnome-calculator-42.1.ebuild  | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index 6cd1c25a09ac..123ef9777654 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-calculator-41.1.tar.xz 1046092 BLAKE2B 2c9a8757adcb9858f826f303ebcec44b869e3be95f49d2722e57765f187d725f82dda6b1cac1302640d686fdccebbf5c8565c5bbd064d1d647bc5d23434d55ba SHA512 fc0d5c0744c52cd68f076afa29e3028f4998fe04e2e253d267b0350514ebae72172e90a345db69bc13d4ead2c7679416529d7192a34cfd970c7b2773870b9604
 DIST gnome-calculator-42.0.tar.xz 1200548 BLAKE2B d628b1b112a1f4b42e8bbc696cb5c0f5aca969f0fa999a9367e495d93c2e9e01b7a8669dbc057da4aa019d9fa9ce3612210c35949bd9aab2664ebc413324d6fc SHA512 9c28126321fdbd9c60f4d992a37f3081b46de24eaf1a057373b8b905c4ad218145cfeb629b001094b4b137cafee5dcdeaae3920ca95f2ec2d4fbe8ea1ef1b72e
+DIST gnome-calculator-42.1.tar.xz 1199604 BLAKE2B ffb2cd60847aa4365d2624827153bb76f3a142237193c9bb3b924827cca22f7b3fbbd21d02af8e2352bb567fe1bae025e12003769e57716e406b982a6f390563 SHA512 c919322e14fb917b3cb02eb365e806872d0b696f7207b25b0f4eaa192d2994fca83e2470355c20bf119f8fd95734beb9575d0c29e7a7b1bf1a9926c0b5ccf736

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-42.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-42.1.ebuild
new file mode 100644
index 000000000000..346e749e13c0
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-42.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=gui-libs/gtk-4.4.1:4
+	>=gui-libs/libadwaita-1.0.0:1
+	>=gui-libs/gtksourceview-5.3.0:5
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:2.4[vala]
+	gui-libs/gtksourceview:5[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+	# Automagic dep on valadoc - don't bother for now
+	sed -e '/subdir.*doc/d' -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}