[gentoo-commits] repo/gentoo:master commit in: media-sound/picard/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     1346b3983b20ed4c2afa344b67b52f5d08c07a93
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Thu May 26 04:57:11 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Thu May 26 04:57:11 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1346b398

media-sound/picard: bump to 2.8

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/picard/Manifest          |  1 +
 media-sound/picard/picard-2.8.ebuild | 63 ++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/media-sound/picard/Manifest b/media-sound/picard/Manifest
index e2cc2ca1e35b..c267df61c0f8 100644
--- a/media-sound/picard/Manifest
+++ b/media-sound/picard/Manifest
@@ -1 +1,2 @@
 DIST picard-2.7.3.tar.gz 4887533 BLAKE2B 65a10be3dafcdd99e20d6c193d1238b0edfa66425a28c705bd6df0f57f75ddcf874f3bf09cef3c331e583a35f49ec780a63d2960081188081c8f0687f6a0b4d1 SHA512 33cd37ce19e261d14882b4400054c289bf921d3c74313db634f3876bc7f51ecca184aa29a9cb1d673fe799c53eda81de45d23c83caaf2f71b74fe341c258d2f7
+DIST picard-2.8.tar.gz 5060056 BLAKE2B b5ba78c910a615e7e2bab148e83514d4fc929d8dc910dcd07dff3af75b502bc9036eb7843bdd3d95b2e5d07902ffcefb529ad1aa19d101565f9c4e66eba693e2 SHA512 bd5b4e7b457603eb8c1895452a7b00cb5de48e28e72c8f377ad73e49aa272a2d09338ea4585f40f1a8401e860a9be3d210db3f44a39956b200d85aa24a89562c

diff --git a/media-sound/picard/picard-2.8.ebuild b/media-sound/picard/picard-2.8.ebuild
new file mode 100644
index 000000000000..accbc2910dfb
--- /dev/null
+++ b/media-sound/picard/picard-2.8.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/metabrainz/picard"
+	inherit git-r3
+else
+	SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-release-${PV}"
+fi
+
+DESCRIPTION="Cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="discid fingerprints nls"
+
+BDEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/fasteners[${PYTHON_USEDEP}]
+		dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
+		discid? ( dev-python/python-discid[${PYTHON_USEDEP}] )
+	')
+	fingerprints? ( media-libs/chromaprint[tools] )
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}