[gentoo-commits] repo/gentoo:master commit in: app-containers/snapd/

["Zac Medico" <zmedico@gentoo.org>]

commit:     0b4d4cd131501cd1a6b6d496ad8ecd1e13da115b
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Sun May 22 20:52:22 2022 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sun May 22 20:53:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b4d4cd1

app-containers/snapd: drop 2.55.5

Closes: https://bugs.gentoo.org/844586
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-containers/snapd/Manifest            |   1 -
 app-containers/snapd/snapd-2.55.5.ebuild | 183 -------------------------------
 2 files changed, 184 deletions(-)

diff --git a/app-containers/snapd/Manifest b/app-containers/snapd/Manifest
index b5eedff3083b..10c8df4528be 100644
--- a/app-containers/snapd/Manifest
+++ b/app-containers/snapd/Manifest
@@ -1,2 +1 @@
-DIST snapd-2.55.5.tar.xz 6670928 BLAKE2B 3bbc4d0fa8e842a400107934518e0f7d0b4e4a26f70a3538590faea631920229e5ba79d023eeda12da71a1f4fcdaa4476efb858130cac600894c1bf0a54be6e6 SHA512 445d0a21a28c994c2608dcb6ea09f6f53398564b644b1f489ed68f1f48c45281d284cd65699f65f9e0b653ef4efeea771bf3cceeeadb71f1a1267c522587e353
 DIST snapd-2.56.tar.xz 6737568 BLAKE2B 662fa682895501df71396095e22fb4587a97cfe4e156b998118ff524ef3a22bf4e60420111167c263c2815ff34a05b026180e41e926324756450e22a1571fc92 SHA512 d2e9949b449ff65122f1202b2048ed63e3ff404aebd71d9877030c7b23130b6be2f1ef62f47b8b0044344fb4826b2b0c81dbcf5cd464ca16f5b3b170735b6039

diff --git a/app-containers/snapd/snapd-2.55.5.ebuild b/app-containers/snapd/snapd-2.55.5.ebuild
deleted file mode 100644
index 4e8c75f7a53b..000000000000
--- a/app-containers/snapd/snapd-2.55.5.ebuild
+++ /dev/null
@@ -1,183 +0,0 @@
-# Copyright 2020-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-EGO_PN="github.com/snapcore/${PN}"
-inherit autotools bash-completion-r1 flag-o-matic golang-vcs-snapshot linux-info readme.gentoo-r1 systemd xdg-utils
-
-DESCRIPTION="Service and tools for management of snap packages"
-HOMEPAGE="http://snapcraft.io/"
-
-MY_S="${S}/src/github.com/snapcore/${PN}"
-
-SRC_URI="https://github.com/snapcore/${PN}/releases/download/${PV}/${PN}_${PV}.vendor.tar.xz -> ${P}.tar.xz"
-MY_PV=${PV}
-KEYWORDS="~amd64"
-
-LICENSE="GPL-3 Apache-2.0 BSD BSD-2 LGPL-3-with-linking-exception MIT"
-SLOT="0"
-IUSE="apparmor +forced-devmode gtk kde systemd"
-REQUIRED_USE="!forced-devmode? ( apparmor ) systemd"
-
-CONFIG_CHECK="~CGROUPS
-		~CGROUP_DEVICE
-		~CGROUP_FREEZER
-		~NAMESPACES
-		~SQUASHFS
-		~SQUASHFS_ZLIB
-		~SQUASHFS_LZO
-		~SQUASHFS_XZ
-		~BLK_DEV_LOOP
-		~SECCOMP
-		~SECCOMP_FILTER"
-
-RDEPEND="
-	sys-libs/libseccomp:=
-	apparmor? (
-		sec-policy/apparmor-profiles
-		sys-apps/apparmor:=
-	)
-	dev-libs/glib
-	virtual/libudev
-	systemd? ( sys-apps/systemd )
-	sys-libs/libcap:=
-	sys-fs/squashfs-tools[lzma]"
-
-DEPEND="${RDEPEND}"
-
-BDEPEND="
-	>=dev-lang/go-1.9
-	dev-python/docutils
-	sys-devel/gettext
-	sys-fs/xfsprogs"
-
-PDEPEND="sys-auth/polkit[gtk?,kde?]"
-
-README_GENTOO_SUFFIX=""
-
-pkg_setup() {
-	if use apparmor; then
-		CONFIG_CHECK+=" ~SECURITY_APPARMOR"
-	fi
-	linux-info_pkg_setup
-
-	# Seems to have issues building with -O3, switch to -O2
-	replace-flags -O3 -O2
-}
-
-src_prepare() {
-	default
-	# Update apparmor profile to allow libtinfow.so*
-	sed -i 's/libtinfo/libtinfo{,w}/' \
-		"${MY_S}/cmd/snap-confine/snap-confine.apparmor.in" || die
-
-	if ! use forced-devmode; then
-		sed -e 's#return !apparmorFull#if !apparmorFull {\n\t\tpanic("USE=forced-devmode is disabled")\n\t}\n\treturn false#' \
-			-i "${MY_S}/sandbox/forcedevmode.go" || die
-		grep -q 'panic("USE=forced-devmode is disabled")' "${MY_S}/sandbox/forcedevmode.go" || die "failed to disable forced-devmode"
-	fi
-
-	sed -i 's:command -v git >/dev/null:false:' -i "${MY_S}/mkversion.sh" || die
-
-	pushd "${MY_S}" >/dev/null || die
-	./mkversion.sh "${PV}"
-	popd >/dev/null || die
-	pushd "${MY_S}/cmd" >/dev/null || die
-	eautoreconf
-}
-
-src_configure() {
-	SNAPD_MAKEARGS=(
-		"BINDIR=${EPREFIX}/usr/bin"
-		"DBUSSERVICESDIR=${EPREFIX}/usr/share/dbus-1/services"
-		"LIBEXECDIR=${EPREFIX}/usr/lib"
-		"SNAP_MOUNT_DIR=${EPREFIX}/var/lib/snapd/snap"
-		"SYSTEMDSYSTEMUNITDIR=$(systemd_get_systemunitdir)"
-	)
-	export CGO_ENABLED="1"
-	export CGO_CFLAGS="${CFLAGS}"
-	export CGO_CPPFLAGS="${CPPFLAGS}"
-	export CGO_CXXFLAGS="${CXXFLAGS}"
-
-	pushd "${MY_S}/cmd" >/dev/null || die
-	econf --libdir="${EPREFIX}/usr/lib" \
-		--libexecdir="${EPREFIX}/usr/lib/snapd" \
-		$(use_enable apparmor) \
-		--enable-nvidia-biarch \
-		--with-snap-mount-dir="${EPREFIX}/var/lib/snapd/snap"
-}
-
-src_compile() {
-	export -n GOCACHE XDG_CACHE_HOME
-	export GO111MODULE=off GOBIN="${S}/bin" GOPATH="${S}"
-
-	local file
-	for file in "${MY_S}/po/"*.po; do
-		msgfmt "${file}" -o "${file%.po}.mo" || die
-	done
-
-	emake -C "${MY_S}/data" "${SNAPD_MAKEARGS[@]}"
-
-	local -a flags=(-buildmode=pie -ldflags "-s -linkmode external -extldflags '${LDFLAGS}'" -trimpath)
-	local -a staticflags=(-buildmode=pie -ldflags "-s -linkmode external -extldflags '${LDFLAGS} -static'" -trimpath)
-
-	local cmd
-	for cmd in snap snapd snap-bootstrap snap-failure snap-preseed snap-recovery-chooser snap-repair snap-seccomp; do
-		go build -o "${GOBIN}/${cmd}" "${flags[@]}" \
-		    -v -x "github.com/snapcore/${PN}/cmd/${cmd}"
-		[[ -e "${GOBIN}/${cmd}" ]] || die "failed to build ${cmd}"
-	done
-	for cmd in snapctl snap-exec snap-update-ns; do
-		go build -o "${GOBIN}/${cmd}" "${staticflags[@]}" \
-		    -v -x "github.com/snapcore/${PN}/cmd/${cmd}"
-		[[ -e "${GOBIN}/${cmd}" ]] || die "failed to build ${cmd}"
-	done
-}
-
-src_install() {
-	emake -C "${MY_S}/data" install "${SNAPD_MAKEARGS[@]}" DESTDIR="${D}"
-	emake -C "${MY_S}/cmd" install "${SNAPD_MAKEARGS[@]}" DESTDIR="${D}"
-
-	if use apparmor; then
-		mv "${ED}/etc/apparmor.d/usr.lib.snapd.snap-confine"{,.real} || die
-		keepdir /var/lib/snapd/apparmor/profiles
-	fi
-	keepdir /var/lib/snapd/{apparmor/snap-confine,cache,cookie,snap,void}
-	fperms 700 /var/lib/snapd/{cache,cookie}
-
-	dobin "${GOBIN}/"{snap,snapctl}
-	ln "${ED}/usr/bin/snapctl" "${ED}/usr/lib/snapd/snapctl" || die
-
-	exeinto /usr/lib/snapd
-	doexe "${GOBIN}/"{snapd,snap-bootstrap,snap-failure,snap-exec,snap-preseed,snap-recovery-chooser,snap-repair,snap-seccomp,snap-update-ns} \
-		"${MY_S}/"{cmd/snap-discard-ns/snap-discard-ns,cmd/snap-gdb-shim/snap-gdb-shim,cmd/snap-mgmt/snap-mgmt} \
-		"${MY_S}/data/completion/bash/"{complete.sh,etelpmoc.sh,}
-
-	dobashcomp "${MY_S}/data/completion/bash/snap"
-
-	insinto /usr/share/zsh/site-functions
-	doins "${MY_S}/data/completion/zsh/_snap"
-
-	insinto "/usr/share/polkit-1/actions"
-	doins "${MY_S}/data/polkit/io.snapcraft.snapd.policy"
-
-	dodoc "${MY_S}/packaging/ubuntu-16.04/changelog"
-	domo "${MY_S}/po/"*.mo
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-	xdg_desktop_database_update
-
-	if use apparmor && [[ -z ${ROOT} && -e /sys/kernel/security/apparmor/profiles &&
-		$(wc -l < /sys/kernel/security/apparmor/profiles) -gt 0 ]]; then
-		apparmor_parser -r "${EPREFIX}/etc/apparmor.d/usr.lib.snapd.snap-confine.real"
-	fi
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-}