public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2020-07-19 13:51 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2020-07-19 13:51 UTC (permalink / raw
  To: gentoo-commits

commit:     b03533a2de029ac15deabd5f9c418b9b2f6da2d6
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 19 13:51:36 2020 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Sun Jul 19 13:51:36 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b03533a2

dev-lang/cxprolog: fix wxwidgets slot version

Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index b4cf9c3904e..e9054d7a336 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-WX_GTK_VER="3.0"
+WX_GTK_VER="3.0-gtk3"
 VIRTUALX_REQUIRED="manual"
 
 inherit flag-o-matic java-pkg-opt-2 java-ant-2 toolchain-funcs virtualx wxwidgets


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2020-07-19 16:42 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2020-07-19 16:42 UTC (permalink / raw
  To: gentoo-commits

commit:     8043a89ff13ea58bbb5ade4ffa2729c7b7c1e020
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 19 16:41:18 2020 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Sun Jul 19 16:42:05 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8043a89f

dev-lang/cxprolog: restrict virtualx to java+wxwidgets

Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 6 +++++-
 1 file changed, 5 insertions(+), 1 deletion(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index e9054d7a336..69288df6b05 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -90,7 +90,11 @@ cxprolog_src_test() {
 }
 
 src_test() {
-	virtx cxprolog_src_test
+	if use java || use wxwidgets; then
+		virtx cxprolog_src_test
+	else
+		cxprolog_src_test
+	fi
 
 	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
 		|| die "cxprolog unit tests failed"


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2020-09-21 18:55 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2020-09-21 18:55 UTC (permalink / raw
  To: gentoo-commits

commit:     b29fd38aa2ae77e2a62ed00c9dfca40fb7593f57
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 21 18:54:33 2020 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Mon Sep 21 18:55:01 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b29fd38a

dev-lang/cxprolog: specify prolog.java location for unit tests

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index d1b773c84e5..a89a12f52e4 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -93,6 +93,12 @@ src_compile() {
 cxprolog_src_test() {
 	cd "${S}"/pl
 
+	if use java; then
+		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
+		mkdir -p "${test_javadir}" || die
+		ln -s "${S}"/dist/prolog.jar "${test_javadir}"/prolog.jar || die
+	fi
+
 	LD_LIBRARY_PATH="${S}" \
 		"${S}"/cxprolog_shared \
 		--boot "${S}"/cx_dev_boot.pl \


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2021-05-15 17:30 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2021-05-15 17:30 UTC (permalink / raw
  To: gentoo-commits

commit:     ec690dadc27d5dadb43e4556c4890bbde7644387
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Sat May 15 17:29:49 2021 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Sat May 15 17:30:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec690dad

dev-lang/cxprolog: stable on amd64 + x86. Closes 790407

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index a89a12f52e4..77c3bde5c40 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -14,7 +14,7 @@ SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="examples java +readline test wxwidgets"
 RESTRICT="!test? ( test )"
 


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2022-03-20 18:43 Sam James
  0 siblings, 0 replies; 13+ messages in thread
From: Sam James @ 2022-03-20 18:43 UTC (permalink / raw
  To: gentoo-commits

commit:     d569fe8026eb02b0b6323b5c5bc2dd69c58fcfa5
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 20 18:43:24 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Mar 20 18:43:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d569fe80

dev-lang/cxprolog: [QA] fix tc-get* quoting

This can cause build problems for e.g. 32-bit (gcc -m32 ...)

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 8 ++++----
 1 file changed, 4 insertions(+), 4 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index 77c3bde5c40b..24deb0a98e0e 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -74,9 +74,9 @@ src_compile() {
 	emake lib \
 		PREFIX=/usr \
 		TMP_DIR="${S}/tmp" \
-		CC=$(tc-getCC) \
-		CPP=$(tc-getCXX) \
-		LD=$(tc-getLD) \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCXX)" \
+		LD="$(tc-getLD)" \
 		CFLAGS="${CFLAGS}" \
 		LDFLAGS="${LDFLAGS}" \
 		EXT_DEFINES="${CX_EXT_DEFINES}" \


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2022-05-21 15:05 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2022-05-21 15:05 UTC (permalink / raw
  To: gentoo-commits

commit:     67a32840e479420c39a610f71efe97df8b962993
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Sat May 21 15:04:50 2022 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Sat May 21 15:04:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67a32840

dev-lang/cxprolog: fix careless patchname typo

Closes: https://bugs.gentoo.org/846764
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index 494d1b7aef2b..3c949317f178 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -32,7 +32,7 @@ S="${WORKDIR}"/${P}
 
 src_prepare() {
 	eapply "${FILESDIR}"/${P}-portage.patch
-	eapply "${FILESDIR}"/${P}/printf-musl.patch
+	eapply "${FILESDIR}"/${P}-printf-musl.patch
 	eapply "${FILESDIR}"/${P}-test-io.patch
 	eapply_user
 


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2022-08-14 15:11 Keri Harris
  0 siblings, 0 replies; 13+ messages in thread
From: Keri Harris @ 2022-08-14 15:11 UTC (permalink / raw
  To: gentoo-commits

commit:     58d57494d68c409a3844cbbfd091304bc5efda43
Author:     Keri Harris <keri <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 14 15:04:15 2022 +0000
Commit:     Keri Harris <keri <AT> gentoo <DOT> org>
CommitDate: Sun Aug 14 15:04:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58d57494

dev-lang/cxprolog: support building with JDK 11

Closes: https://bugs.gentoo.org/855206
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Keri Harris <keri <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 7 +++++--
 1 file changed, 5 insertions(+), 2 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
index 3c949317f178..aea94ab537f6 100644
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
@@ -14,7 +14,7 @@ SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="amd64 x86"
+KEYWORDS="~amd64 ~x86"
 IUSE="examples java +readline test wxwidgets"
 RESTRICT="!test? ( test )"
 
@@ -59,7 +59,10 @@ src_compile() {
 		local java_arch
 		use x86 && java_arch=i386
 		use amd64 && java_arch=amd64
-		CX_JVM="${JAVA_HOME}/jre/lib/${java_arch}/server"
+		local CX_JVM
+		for i in jre/lib/${java_arch}/server lib/server; do
+			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
+		done
 		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
 		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
 		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-04-18 16:48 Pacho Ramos
  0 siblings, 0 replies; 13+ messages in thread
From: Pacho Ramos @ 2024-04-18 16:48 UTC (permalink / raw
  To: gentoo-commits

commit:     c48bf14e83b4f8f217a28ebb4af0d60c376b49a5
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 18 16:47:30 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Apr 18 16:47:33 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c48bf14e

dev-lang/cxprolog: migrate to wxGTK 3.2

Closes: https://bugs.gentoo.org/917438
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild | 144 ++++++++++++++++++++++++++++
 1 file changed, 144 insertions(+)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild
new file mode 100644
index 000000000000..c6949fbe3d57
--- /dev/null
+++ b/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WX_GTK_VER="3.2-gtk3"
+VIRTUALX_REQUIRED="manual"
+
+inherit flag-o-matic java-pkg-opt-2 java-ant-2 toolchain-funcs virtualx wxwidgets
+
+DESCRIPTION="A WAM based Prolog system"
+HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog"
+SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples java +readline test wxwidgets"
+RESTRICT="!test? ( test )"
+
+RDEPEND="readline? ( sys-libs/readline:= )
+	java? ( >=virtual/jdk-1.8:= )
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+
+DEPEND="${RDEPEND}
+	test? (
+		java? ( ${VIRTUALX_DEPEND} )
+		wxwidgets? ( ${VIRTUALX_DEPEND} )
+	)"
+
+S="${WORKDIR}"/${P}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${P}-portage.patch
+	eapply "${FILESDIR}"/${P}-printf-musl.patch
+	eapply "${FILESDIR}"/${P}-test-io.patch
+	eapply_user
+
+	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
+	cp "${FILESDIR}"/build.xml "${S}"/build.xml || die
+	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
+	rm -f "${S}"/pl/test_file_io_1.txt
+
+	use wxwidgets && setup-wxwidgets
+}
+
+src_compile() {
+	local CX_EXT_DEFINES
+	local CX_EXT_CFLAGS
+	local CX_EXT_LDFLAGS
+	local CX_EXT_LIBS
+
+	if use readline; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
+		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
+	fi
+
+	if use java; then
+		local java_arch
+		use x86 && java_arch=i386
+		use amd64 && java_arch=amd64
+		local CX_JVM
+		for i in jre/lib/${java_arch}/server lib/server; do
+			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
+		done
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
+		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
+		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
+	fi
+
+	if use wxwidgets; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
+		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
+	fi
+
+	emake lib \
+		PREFIX=/usr \
+		TMP_DIR="${S}/tmp" \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCXX)" \
+		LD="$(tc-getLD)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		EXT_DEFINES="${CX_EXT_DEFINES}" \
+		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
+		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
+		EXT_LIBS="${CX_EXT_LIBS}"
+
+	if use java; then
+		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
+		eant jar
+	fi
+}
+
+cxprolog_src_test() {
+	cd "${S}"/pl
+
+	if use java; then
+		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
+		mkdir -p "${test_javadir}" || die
+		ln -s "${S}"/dist/prolog.jar "${test_javadir}"/prolog.jar || die
+	fi
+
+	LD_LIBRARY_PATH="${S}" \
+		"${S}"/cxprolog_shared \
+		--boot "${S}"/cx_dev_boot.pl \
+		--script "${S}"/pl/test_all.pl \
+		| tee "${S}"/cxprolog_test.log
+}
+
+src_test() {
+	if use java || use wxwidgets; then
+		virtx cxprolog_src_test
+	else
+		cxprolog_src_test
+	fi
+
+	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
+		|| die "cxprolog unit tests failed"
+}
+
+src_install() {
+	newbin cxprolog_shared cxprolog
+	dolib.so libcxprolog.so
+
+	insinto /usr/$(get_libdir)/cxprolog
+	doins lib/cxprolog/lib.pl
+
+	insinto /usr/share/${PN}/pl
+	doins pl/*.{pl,txt}
+
+	if use java; then
+		insinto /usr/$(get_libdir)/cxprolog/java
+		doins dist/prolog.jar
+	fi
+
+	dodoc ChangeLog.txt MANUAL.txt README.txt
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-05-05  7:25 Miroslav Šulc
  0 siblings, 0 replies; 13+ messages in thread
From: Miroslav Šulc @ 2024-05-05  7:25 UTC (permalink / raw
  To: gentoo-commits

commit:     4be978124113d5183dd7e7f6d576999278f812fd
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Sun May  5 07:00:13 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sun May  5 07:25:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4be97812

dev-lang/cxprolog: drop 0.98.2

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/36544
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2.ebuild | 144 -------------------------------
 1 file changed, 144 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
deleted file mode 100644
index aea94ab537f6..000000000000
--- a/dev-lang/cxprolog/cxprolog-0.98.2.ebuild
+++ /dev/null
@@ -1,144 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-WX_GTK_VER="3.0-gtk3"
-VIRTUALX_REQUIRED="manual"
-
-inherit flag-o-matic java-pkg-opt-2 java-ant-2 toolchain-funcs virtualx wxwidgets
-
-DESCRIPTION="A WAM based Prolog system"
-HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog"
-SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="examples java +readline test wxwidgets"
-RESTRICT="!test? ( test )"
-
-RDEPEND="readline? ( sys-libs/readline:= )
-	java? ( >=virtual/jdk-1.8:= )
-	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
-
-DEPEND="${RDEPEND}
-	test? (
-		java? ( ${VIRTUALX_DEPEND} )
-		wxwidgets? ( ${VIRTUALX_DEPEND} )
-	)"
-
-S="${WORKDIR}"/${P}
-
-src_prepare() {
-	eapply "${FILESDIR}"/${P}-portage.patch
-	eapply "${FILESDIR}"/${P}-printf-musl.patch
-	eapply "${FILESDIR}"/${P}-test-io.patch
-	eapply_user
-
-	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
-	cp "${FILESDIR}"/build.xml "${S}"/build.xml || die
-	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
-	rm -f "${S}"/pl/test_file_io_1.txt
-
-	use wxwidgets && setup-wxwidgets
-}
-
-src_compile() {
-	local CX_EXT_DEFINES
-	local CX_EXT_CFLAGS
-	local CX_EXT_LDFLAGS
-	local CX_EXT_LIBS
-
-	if use readline; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
-		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
-	fi
-
-	if use java; then
-		local java_arch
-		use x86 && java_arch=i386
-		use amd64 && java_arch=amd64
-		local CX_JVM
-		for i in jre/lib/${java_arch}/server lib/server; do
-			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
-		done
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
-		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
-		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
-	fi
-
-	if use wxwidgets; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
-		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
-	fi
-
-	emake lib \
-		PREFIX=/usr \
-		TMP_DIR="${S}/tmp" \
-		CC="$(tc-getCC)" \
-		CPP="$(tc-getCXX)" \
-		LD="$(tc-getLD)" \
-		CFLAGS="${CFLAGS}" \
-		LDFLAGS="${LDFLAGS}" \
-		EXT_DEFINES="${CX_EXT_DEFINES}" \
-		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
-		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
-		EXT_LIBS="${CX_EXT_LIBS}"
-
-	if use java; then
-		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
-		eant jar
-	fi
-}
-
-cxprolog_src_test() {
-	cd "${S}"/pl
-
-	if use java; then
-		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
-		mkdir -p "${test_javadir}" || die
-		ln -s "${S}"/dist/prolog.jar "${test_javadir}"/prolog.jar || die
-	fi
-
-	LD_LIBRARY_PATH="${S}" \
-		"${S}"/cxprolog_shared \
-		--boot "${S}"/cx_dev_boot.pl \
-		--script "${S}"/pl/test_all.pl \
-		| tee "${S}"/cxprolog_test.log
-}
-
-src_test() {
-	if use java || use wxwidgets; then
-		virtx cxprolog_src_test
-	else
-		cxprolog_src_test
-	fi
-
-	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
-		|| die "cxprolog unit tests failed"
-}
-
-src_install() {
-	newbin cxprolog_shared cxprolog
-	dolib.so libcxprolog.so
-
-	insinto /usr/$(get_libdir)/cxprolog
-	doins lib/cxprolog/lib.pl
-
-	insinto /usr/share/${PN}/pl
-	doins pl/*.{pl,txt}
-
-	if use java; then
-		insinto /usr/$(get_libdir)/cxprolog/java
-		doins dist/prolog.jar
-	fi
-
-	dodoc ChangeLog.txt MANUAL.txt README.txt
-
-	if use examples; then
-		dodoc -r examples
-	fi
-}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-06-19  8:12 Miroslav Šulc
  0 siblings, 0 replies; 13+ messages in thread
From: Miroslav Šulc @ 2024-06-19  8:12 UTC (permalink / raw
  To: gentoo-commits

commit:     f1ddc1263008cc3a468688c1c166e9867d789d3f
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Wed Jun 12 07:14:06 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Jun 19 08:10:48 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1ddc126

dev-lang/cxprolog: rewrite with java-pkg-simple

- Moves virtual/jdk from RDEPEND to DEPEND
- Adds virtual/jre to RDEPEND

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/36770/commits/d10f5bed48ee0840449957dd97982603028b7972
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild | 149 ++++++++++++++++++++++++++++
 1 file changed, 149 insertions(+)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
new file mode 100644
index 000000000000..f1daaff7b66c
--- /dev/null
+++ b/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WX_GTK_VER="3.2-gtk3"
+VIRTUALX_REQUIRED="manual"
+
+inherit flag-o-matic java-pkg-opt-2 java-pkg-2 java-pkg-simple toolchain-funcs virtualx wxwidgets
+
+DESCRIPTION="A WAM based Prolog system"
+HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog/"
+SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
+S="${WORKDIR}"/${P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples java +readline test wxwidgets"
+RESTRICT="!test? ( test )"
+
+COMMON_DEP="
+	readline? ( sys-libs/readline:= )
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+"
+
+RDEPEND="${COMMON_DEP}
+	java? ( >=virtual/jre-1.8:* )"
+
+DEPEND="${COMMON_DEP}
+	java? ( >=virtual/jdk-1.8:* )
+	test? (
+		java? ( ${VIRTUALX_DEPEND} )
+		wxwidgets? ( ${VIRTUALX_DEPEND} )
+	)"
+
+src_prepare() {
+	eapply "${FILESDIR}"/${P}-portage.patch
+	eapply "${FILESDIR}"/${P}-printf-musl.patch
+	eapply "${FILESDIR}"/${P}-test-io.patch
+	eapply_user
+
+	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
+	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
+	rm -f "${S}"/pl/test_file_io_1.txt
+
+	use wxwidgets && setup-wxwidgets
+
+	java-pkg_clean
+}
+
+src_compile() {
+	local CX_EXT_DEFINES
+	local CX_EXT_CFLAGS
+	local CX_EXT_LDFLAGS
+	local CX_EXT_LIBS
+
+	if use readline; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
+		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
+	fi
+
+	if use java; then
+		local java_arch
+		use x86 && java_arch=i386
+		use amd64 && java_arch=amd64
+		local CX_JVM
+		for i in jre/lib/${java_arch}/server lib/server; do
+			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
+		done
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
+		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
+		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
+	fi
+
+	if use wxwidgets; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
+		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
+	fi
+
+	emake lib \
+		PREFIX=/usr \
+		TMP_DIR="${S}/tmp" \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCXX)" \
+		LD="$(tc-getLD)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		EXT_DEFINES="${CX_EXT_DEFINES}" \
+		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
+		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
+		EXT_LIBS="${CX_EXT_LIBS}"
+
+	if use java; then
+		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
+		java-pkg-simple_src_compile
+	fi
+}
+
+cxprolog_src_test() {
+	cd "${S}"/pl
+
+	if use java; then
+		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
+		mkdir -p "${test_javadir}" || die
+		ln -s "${S}"/cxprolog.jar "${test_javadir}"/prolog.jar || die
+	fi
+
+	LD_LIBRARY_PATH="${S}" \
+		"${S}"/cxprolog_shared \
+		--boot "${S}"/cx_dev_boot.pl \
+		--script "${S}"/pl/test_all.pl \
+		| tee "${S}"/cxprolog_test.log
+}
+
+src_test() {
+	if use java || use wxwidgets; then
+		virtx cxprolog_src_test
+	else
+		cxprolog_src_test
+	fi
+
+	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
+		|| die "cxprolog unit tests failed"
+}
+
+src_install() {
+	newbin cxprolog_shared cxprolog
+	dolib.so libcxprolog.so
+
+	insinto /usr/$(get_libdir)/cxprolog
+	doins lib/cxprolog/lib.pl
+
+	insinto /usr/share/${PN}/pl
+	doins pl/*.{pl,txt}
+
+	if use java; then
+		java-pkg_jarinto /usr/$(get_libdir)/cxprolog/java
+		java-pkg_newjar cxprolog.jar prolog.jar
+	fi
+
+	dodoc ChangeLog.txt MANUAL.txt README.txt
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-06-19  8:34 Miroslav Šulc
  0 siblings, 0 replies; 13+ messages in thread
From: Miroslav Šulc @ 2024-06-19  8:34 UTC (permalink / raw
  To: gentoo-commits

commit:     30210e9493d7f7d41c01e62b2cc5cb7112cbcb26
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Wed Jun 19 08:31:22 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Jun 19 08:34:45 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30210e94

Revert "dev-lang/cxprolog: rewrite with java-pkg-simple"

This reverts commit f1ddc1263008cc3a468688c1c166e9867d789d3f.

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/37214
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild | 149 ----------------------------
 1 file changed, 149 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
deleted file mode 100644
index f1daaff7b66c..000000000000
--- a/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
+++ /dev/null
@@ -1,149 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-WX_GTK_VER="3.2-gtk3"
-VIRTUALX_REQUIRED="manual"
-
-inherit flag-o-matic java-pkg-opt-2 java-pkg-2 java-pkg-simple toolchain-funcs virtualx wxwidgets
-
-DESCRIPTION="A WAM based Prolog system"
-HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog/"
-SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
-S="${WORKDIR}"/${P}
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="examples java +readline test wxwidgets"
-RESTRICT="!test? ( test )"
-
-COMMON_DEP="
-	readline? ( sys-libs/readline:= )
-	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
-"
-
-RDEPEND="${COMMON_DEP}
-	java? ( >=virtual/jre-1.8:* )"
-
-DEPEND="${COMMON_DEP}
-	java? ( >=virtual/jdk-1.8:* )
-	test? (
-		java? ( ${VIRTUALX_DEPEND} )
-		wxwidgets? ( ${VIRTUALX_DEPEND} )
-	)"
-
-src_prepare() {
-	eapply "${FILESDIR}"/${P}-portage.patch
-	eapply "${FILESDIR}"/${P}-printf-musl.patch
-	eapply "${FILESDIR}"/${P}-test-io.patch
-	eapply_user
-
-	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
-	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
-	rm -f "${S}"/pl/test_file_io_1.txt
-
-	use wxwidgets && setup-wxwidgets
-
-	java-pkg_clean
-}
-
-src_compile() {
-	local CX_EXT_DEFINES
-	local CX_EXT_CFLAGS
-	local CX_EXT_LDFLAGS
-	local CX_EXT_LIBS
-
-	if use readline; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
-		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
-	fi
-
-	if use java; then
-		local java_arch
-		use x86 && java_arch=i386
-		use amd64 && java_arch=amd64
-		local CX_JVM
-		for i in jre/lib/${java_arch}/server lib/server; do
-			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
-		done
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
-		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
-		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
-	fi
-
-	if use wxwidgets; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
-		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
-	fi
-
-	emake lib \
-		PREFIX=/usr \
-		TMP_DIR="${S}/tmp" \
-		CC="$(tc-getCC)" \
-		CPP="$(tc-getCXX)" \
-		LD="$(tc-getLD)" \
-		CFLAGS="${CFLAGS}" \
-		LDFLAGS="${LDFLAGS}" \
-		EXT_DEFINES="${CX_EXT_DEFINES}" \
-		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
-		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
-		EXT_LIBS="${CX_EXT_LIBS}"
-
-	if use java; then
-		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
-		java-pkg-simple_src_compile
-	fi
-}
-
-cxprolog_src_test() {
-	cd "${S}"/pl
-
-	if use java; then
-		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
-		mkdir -p "${test_javadir}" || die
-		ln -s "${S}"/cxprolog.jar "${test_javadir}"/prolog.jar || die
-	fi
-
-	LD_LIBRARY_PATH="${S}" \
-		"${S}"/cxprolog_shared \
-		--boot "${S}"/cx_dev_boot.pl \
-		--script "${S}"/pl/test_all.pl \
-		| tee "${S}"/cxprolog_test.log
-}
-
-src_test() {
-	if use java || use wxwidgets; then
-		virtx cxprolog_src_test
-	else
-		cxprolog_src_test
-	fi
-
-	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
-		|| die "cxprolog unit tests failed"
-}
-
-src_install() {
-	newbin cxprolog_shared cxprolog
-	dolib.so libcxprolog.so
-
-	insinto /usr/$(get_libdir)/cxprolog
-	doins lib/cxprolog/lib.pl
-
-	insinto /usr/share/${PN}/pl
-	doins pl/*.{pl,txt}
-
-	if use java; then
-		java-pkg_jarinto /usr/$(get_libdir)/cxprolog/java
-		java-pkg_newjar cxprolog.jar prolog.jar
-	fi
-
-	dodoc ChangeLog.txt MANUAL.txt README.txt
-
-	if use examples; then
-		dodoc -r examples
-	fi
-}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-08-27  7:45 Miroslav Šulc
  0 siblings, 0 replies; 13+ messages in thread
From: Miroslav Šulc @ 2024-08-27  7:45 UTC (permalink / raw
  To: gentoo-commits

commit:     c926aba47473b4b4ee4094bd020f29218783c3e7
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Mon Jul  1 07:12:32 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Tue Aug 27 07:42:15 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c926aba4

dev-lang/cxprolog: rewrite with java-pkg-simple

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/37468/commits/4c4c144d33e7ecd8281357c4673012e0538fb0ac
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild | 150 ++++++++++++++++++++++++++++
 1 file changed, 150 insertions(+)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
new file mode 100644
index 000000000000..32ad5e2f536a
--- /dev/null
+++ b/dev-lang/cxprolog/cxprolog-0.98.2-r2.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WX_GTK_VER="3.2-gtk3"
+VIRTUALX_REQUIRED="manual"
+
+inherit flag-o-matic java-pkg-opt-2 java-pkg-simple toolchain-funcs virtualx wxwidgets
+
+DESCRIPTION="A WAM based Prolog system"
+HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog/"
+SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
+S="${WORKDIR}"/${P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples java +readline test wxwidgets"
+RESTRICT="!test? ( test )"
+
+COMMON_DEP="
+	readline? ( sys-libs/readline:= )
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+"
+
+DEPEND="${COMMON_DEP}
+	java? ( >=virtual/jdk-1.8:* )
+	test? (
+		java? ( ${VIRTUALX_DEPEND} )
+		wxwidgets? ( ${VIRTUALX_DEPEND} )
+	)"
+
+RDEPEND="${COMMON_DEP}
+	java? ( >=virtual/jre-1.8:* )"
+
+DOCS=( ChangeLog.txt MANUAL.txt README.txt )
+PATCHES=(
+	"${FILESDIR}"/${P}-portage.patch
+	"${FILESDIR}"/${P}-printf-musl.patch
+	"${FILESDIR}"/${P}-test-io.patch
+)
+
+src_prepare() {
+	default #780585
+	use java && java-pkg-opt-2_src_prepare && java-pkg_clean
+
+	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
+	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
+	rm -f "${S}"/pl/test_file_io_1.txt
+
+	use wxwidgets && setup-wxwidgets
+}
+
+src_compile() {
+	local CX_EXT_DEFINES
+	local CX_EXT_CFLAGS
+	local CX_EXT_LDFLAGS
+	local CX_EXT_LIBS
+
+	if use readline; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
+		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
+	fi
+
+	if use java; then
+		local java_arch
+		use x86 && java_arch=i386
+		use amd64 && java_arch=amd64
+		local CX_JVM
+		for i in jre/lib/${java_arch}/server lib/server; do
+			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
+		done
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
+		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
+		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
+	fi
+
+	if use wxwidgets; then
+		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
+		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
+		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
+	fi
+
+	emake lib \
+		PREFIX=/usr \
+		TMP_DIR="${S}/tmp" \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCXX)" \
+		LD="$(tc-getLD)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		EXT_DEFINES="${CX_EXT_DEFINES}" \
+		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
+		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
+		EXT_LIBS="${CX_EXT_LIBS}"
+
+	if use java; then
+		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
+		java-pkg-simple_src_compile
+	fi
+}
+
+cxprolog_src_test() {
+	cd "${S}"/pl
+
+	if use java; then
+		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
+		mkdir -p "${test_javadir}" || die
+		ln -s "${S}"/cxprolog.jar "${test_javadir}"/prolog.jar || die
+	fi
+
+	LD_LIBRARY_PATH="${S}" \
+		"${S}"/cxprolog_shared \
+		--boot "${S}"/cx_dev_boot.pl \
+		--script "${S}"/pl/test_all.pl \
+		| tee "${S}"/cxprolog_test.log
+}
+
+src_test() {
+	if use java || use wxwidgets; then
+		virtx cxprolog_src_test
+	else
+		cxprolog_src_test
+	fi
+
+	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
+		|| die "cxprolog unit tests failed"
+}
+
+src_install() {
+	newbin cxprolog_shared cxprolog
+	dolib.so libcxprolog.so
+
+	insinto /usr/$(get_libdir)/cxprolog
+	doins lib/cxprolog/lib.pl
+
+	insinto /usr/share/${PN}/pl
+	doins pl/*.{pl,txt}
+
+	if use java; then
+		java-pkg_jarinto /usr/$(get_libdir)/cxprolog/java
+		java-pkg_newjar cxprolog.jar prolog.jar
+	fi
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/
@ 2024-09-01  9:56 Miroslav Šulc
  0 siblings, 0 replies; 13+ messages in thread
From: Miroslav Šulc @ 2024-09-01  9:56 UTC (permalink / raw
  To: gentoo-commits

commit:     7399994229431cb5c12d5666a93c33caa9e84d18
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Mon Jul  1 07:13:26 2024 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sun Sep  1 09:56:24 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73999942

dev-lang/cxprolog: drop 0.98.2-r1

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild | 144 ----------------------------
 1 file changed, 144 deletions(-)

diff --git a/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild b/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild
deleted file mode 100644
index c6949fbe3d57..000000000000
--- a/dev-lang/cxprolog/cxprolog-0.98.2-r1.ebuild
+++ /dev/null
@@ -1,144 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-WX_GTK_VER="3.2-gtk3"
-VIRTUALX_REQUIRED="manual"
-
-inherit flag-o-matic java-pkg-opt-2 java-ant-2 toolchain-funcs virtualx wxwidgets
-
-DESCRIPTION="A WAM based Prolog system"
-HOMEPAGE="http://ctp.di.fct.unl.pt/~amd/cxprolog"
-SRC_URI="http://ctp.di.fct.unl.pt/~amd/cxprolog/cxunix/${P}.src.tgz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="examples java +readline test wxwidgets"
-RESTRICT="!test? ( test )"
-
-RDEPEND="readline? ( sys-libs/readline:= )
-	java? ( >=virtual/jdk-1.8:= )
-	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
-
-DEPEND="${RDEPEND}
-	test? (
-		java? ( ${VIRTUALX_DEPEND} )
-		wxwidgets? ( ${VIRTUALX_DEPEND} )
-	)"
-
-S="${WORKDIR}"/${P}
-
-src_prepare() {
-	eapply "${FILESDIR}"/${P}-portage.patch
-	eapply "${FILESDIR}"/${P}-printf-musl.patch
-	eapply "${FILESDIR}"/${P}-test-io.patch
-	eapply_user
-
-	sed -i -e "s|lib/cxprolog|$(get_libdir)/cxprolog|" "${S}"/src/FileSys.c || die
-	cp "${FILESDIR}"/build.xml "${S}"/build.xml || die
-	cp "${FILESDIR}"/cx_dev_boot.pl "${S}"/cx_dev_boot.pl || die
-	rm -f "${S}"/pl/test_file_io_1.txt
-
-	use wxwidgets && setup-wxwidgets
-}
-
-src_compile() {
-	local CX_EXT_DEFINES
-	local CX_EXT_CFLAGS
-	local CX_EXT_LDFLAGS
-	local CX_EXT_LIBS
-
-	if use readline; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_READLINE"
-		CX_EXT_LIBS="$CX_EXT_LIBS -lreadline"
-	fi
-
-	if use java; then
-		local java_arch
-		use x86 && java_arch=i386
-		use amd64 && java_arch=amd64
-		local CX_JVM
-		for i in jre/lib/${java_arch}/server lib/server; do
-			[[ -f ${JAVA_HOME}/${i}/libjvm.so ]] && CX_JVM=${JAVA_HOME}/${i}
-		done
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_JAVA"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(java-pkg_get-jni-cflags)"
-		CX_EXT_LDFLAGS="$CX_EXT_LDFLAGS -Wl,-rpath,${CX_JVM}"
-		CX_EXT_LIBS="$CX_EXT_LIBS -L${CX_JVM} -ljvm"
-	fi
-
-	if use wxwidgets; then
-		CX_EXT_DEFINES="$CX_EXT_DEFINES -DUSE_WXWIDGETS"
-		CX_EXT_CFLAGS="$CX_EXT_CFLAGS $(${WX_CONFIG} --cflags)"
-		CX_EXT_LIBS="$CX_EXT_LIBS $(${WX_CONFIG} --libs)"
-	fi
-
-	emake lib \
-		PREFIX=/usr \
-		TMP_DIR="${S}/tmp" \
-		CC="$(tc-getCC)" \
-		CPP="$(tc-getCXX)" \
-		LD="$(tc-getLD)" \
-		CFLAGS="${CFLAGS}" \
-		LDFLAGS="${LDFLAGS}" \
-		EXT_DEFINES="${CX_EXT_DEFINES}" \
-		EXT_CFLAGS="-Wall ${CX_EXT_CFLAGS}" \
-		EXT_LDFLAGS="${CX_EXT_LDFLAGS}" \
-		EXT_LIBS="${CX_EXT_LIBS}"
-
-	if use java; then
-		JAVA_SRC_DIR="${S}/lib/cxprolog/java"
-		eant jar
-	fi
-}
-
-cxprolog_src_test() {
-	cd "${S}"/pl
-
-	if use java; then
-		local test_javadir="${S}"/pl/$(get_libdir)/cxprolog/java
-		mkdir -p "${test_javadir}" || die
-		ln -s "${S}"/dist/prolog.jar "${test_javadir}"/prolog.jar || die
-	fi
-
-	LD_LIBRARY_PATH="${S}" \
-		"${S}"/cxprolog_shared \
-		--boot "${S}"/cx_dev_boot.pl \
-		--script "${S}"/pl/test_all.pl \
-		| tee "${S}"/cxprolog_test.log
-}
-
-src_test() {
-	if use java || use wxwidgets; then
-		virtx cxprolog_src_test
-	else
-		cxprolog_src_test
-	fi
-
-	grep -q "ALL THE TESTS PASSED" "${S}"/cxprolog_test.log \
-		|| die "cxprolog unit tests failed"
-}
-
-src_install() {
-	newbin cxprolog_shared cxprolog
-	dolib.so libcxprolog.so
-
-	insinto /usr/$(get_libdir)/cxprolog
-	doins lib/cxprolog/lib.pl
-
-	insinto /usr/share/${PN}/pl
-	doins pl/*.{pl,txt}
-
-	if use java; then
-		insinto /usr/$(get_libdir)/cxprolog/java
-		doins dist/prolog.jar
-	fi
-
-	dodoc ChangeLog.txt MANUAL.txt README.txt
-
-	if use examples; then
-		dodoc -r examples
-	fi
-}


^ permalink raw reply related	[flat|nested] 13+ messages in thread
end of thread, other threads:[~2024-09-01  9:56 UTC | newest]

Thread overview: 13+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2022-05-21 15:05 [gentoo-commits] repo/gentoo:master commit in: dev-lang/cxprolog/ Keri Harris
  -- strict thread matches above, loose matches on Subject: below --
2024-09-01  9:56 Miroslav Šulc
2024-08-27  7:45 Miroslav Šulc
2024-06-19  8:34 Miroslav Šulc
2024-06-19  8:12 Miroslav Šulc
2024-05-05  7:25 Miroslav Šulc
2024-04-18 16:48 Pacho Ramos
2022-08-14 15:11 Keri Harris
2022-03-20 18:43 Sam James
2021-05-15 17:30 Keri Harris
2020-09-21 18:55 Keri Harris
2020-07-19 16:42 Keri Harris
2020-07-19 13:51 Keri Harris

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox