[gentoo-commits] repo/gentoo:master commit in: xfce-base/garcon/

["Michał Górny" <mgorny@gentoo.org>]

commit:     fe1f9f0c55364fe81c91d769d511758396a866cf
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon May 16 06:57:46 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 16 07:55:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fe1f9f0c

xfce-base/garcon: Bump to 4.17.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/garcon/Manifest             |  1 +
 xfce-base/garcon/garcon-4.17.0.ebuild | 55 +++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/xfce-base/garcon/Manifest b/xfce-base/garcon/Manifest
index 03e685399010..1b39242e3d7a 100644
--- a/xfce-base/garcon/Manifest
+++ b/xfce-base/garcon/Manifest
@@ -1 +1,2 @@
 DIST garcon-0.8.0.tar.bz2 539061 BLAKE2B 8d7b207fdb325d060c3ecfa5e2574961082706c5a4af59cabebad9d3c915228085dc32442521018bfb7da2d3c169445ac270c00c381e666bfda8774329a60cfc SHA512 708c68c31c0d3d89ecdde4790594837af0d065ecb805131fd7db2eb4c433c0523f44d51f2040f7bf9af729537e5f9e89ed06a435fc0c4e6113db00ad78ba8ce0
+DIST garcon-4.17.0.tar.bz2 545911 BLAKE2B 0286233a5fc7769955eeb8901a64cd2087d47b28bbb05ae884c6d867e4374191d7dbb0bbc54decf7d4370ae31127d6d5acf63c77d1d18889efa5388bc5d4e5e3 SHA512 6fc88177b8f1b8630fe1f0954151ff60a9957bd7239452317e5e942e70576b996aa59f87e249feb4dfaa256972c3a028323a6fd02826d9b5e4a90df47c7f2361

diff --git a/xfce-base/garcon/garcon-4.17.0.ebuild b/xfce-base/garcon/garcon-4.17.0.ebuild
new file mode 100644
index 000000000000..c96238763769
--- /dev/null
+++ b/xfce-base/garcon/garcon-4.17.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Xfce's freedesktop.org specification compatible menu implementation library"
+HOMEPAGE="https://docs.xfce.org/xfce/garcon/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ FDL-1.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="introspection"
+
+DEPEND="
+	>=dev-libs/glib-2.50.0
+	>=x11-libs/gtk+-3.20:3
+	>=xfce-base/libxfce4util-4.15.6:=[introspection?]
+	>=xfce-base/libxfce4ui-4.15.7:=[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}