[gentoo-commits] repo/gentoo:master commit in: media-video/bino/

["Sam James" <sam@gentoo.org>]

commit:     554cf452b104b8e65b24a4cfc2c9a2668fceb3f7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun May 15 23:42:18 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun May 15 23:42:26 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=554cf452

media-video/bino: add 1.6.8

Closes: https://bugs.gentoo.org/765724
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-video/bino/Manifest          |  1 +
 media-video/bino/bino-1.6.8.ebuild | 65 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/media-video/bino/Manifest b/media-video/bino/Manifest
index 8a9626ab08b9..b16b13a4d7a3 100644
--- a/media-video/bino/Manifest
+++ b/media-video/bino/Manifest
@@ -1 +1,2 @@
 DIST bino-1.6.7.tar.xz 825068 BLAKE2B d9019a793838f33ea1315849aa994b20a1c6127995315dc03972fe6c64a742c73434c07ba06402a1e2bd5357781d18aaf3d19ab2d61788745b2aa99ad3f4c6f4 SHA512 ae8f72b200100664b9fd55963371ce64a2f39e240676494d69b422d662f2295560ba458eb04707b82f88d3c6b3fab98a1ecb40d74799300f96b8eb8be680c9b8
+DIST bino-1.6.8.tar.xz 836712 BLAKE2B 801d6f1ffbf1a7fbaabcdbb2c4bd649662d3b14b08189431a418702177f5de28a8961763c83962fd72cbf6f762fad34ed0b616efc68a723f65b6c72823618897 SHA512 d8cf5be356add4ed3fb36673038b5ffd92d0dc840798cc616fa4b11fec221c7f114347dfc7cdb7a3a24c5599b56301cddc99f84d3862d8e874612960281319cc

diff --git a/media-video/bino/bino-1.6.8.ebuild b/media-video/bino/bino-1.6.8.ebuild
new file mode 100644
index 000000000000..6e75a6e0da47
--- /dev/null
+++ b/media-video/bino/bino-1.6.8.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic qmake-utils xdg
+
+DESCRIPTION="Stereoscopic and multi-display media player"
+HOMEPAGE="https://bino3d.org/"
+SRC_URI="https://bino3d.org/releases/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc lirc video_cards_nvidia"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtwidgets:5
+	>=media-libs/glew-1.6.0:0=
+	>=media-libs/libass-0.9.9
+	>=media-libs/openal-1.15.1
+	virtual/libintl
+	>=media-video/ffmpeg-0.7:0=
+	lirc? ( app-misc/lirc )
+	video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	if use video_cards_nvidia; then
+		append-cppflags "-I${ESYSROOT}/usr/include/NVCtrl"
+		append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/opengl/nvidia/lib -L${ESYSROOT}/usr/$(get_libdir)"
+		append-libs "Xext"
+	fi
+
+	if use lirc; then
+		append-cppflags "-I${ESYSROOT}/usr/include/lirc"
+		append-libs "lirc_client"
+	fi
+
+	# Fix a compilation error because of a multiple definitions error in glew
+	append-ldflags "-zmuldefs"
+
+	export MOC="$(qt5_get_bindir)"/moc
+	export RCC="$(qt5_get_bindir)"/rcc
+
+	econf \
+		$(use_with video_cards_nvidia xnvctrl) \
+		$(use_with lirc) \
+		$(use_enable debug) \
+		--without-equalizer \
+		--with-qt-version=5
+}
+
+src_install() {
+	default
+
+	if ! use doc; then
+		rm -rf "${ED}"/usr/share/doc/${PF}/html || die
+	fi
+}