[gentoo-commits] repo/gentoo:master commit in: dev-ruby/sprockets/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     490850e4d6f5296b12186108b65aa7643267dbb2
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun May 15 07:42:10 2022 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun May 15 07:50:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=490850e4

dev-ruby/sprockets: update EAPI 6 -> 8, add ruby30

Add ERB deprecation commit as well, already merged upstream but never
released.

Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/sprockets/sprockets-3.7.2-r2.ebuild | 63 ++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

diff --git a/dev-ruby/sprockets/sprockets-3.7.2-r2.ebuild b/dev-ruby/sprockets/sprockets-3.7.2-r2.ebuild
new file mode 100644
index 000000000000..de73a55d6b0f
--- /dev/null
+++ b/dev-ruby/sprockets/sprockets-3.7.2-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_GEMSPEC="sprockets.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Ruby library for compiling and serving web assets"
+HOMEPAGE="https://github.com/rails/sprockets"
+SRC_URI="https://github.com/rails/sprockets/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+IUSE=""
+
+PATCHES=( "${FILESDIR}/${P}-erb-deprecation.patch" "${FILESDIR}/${P}-kwargs.patch" )
+
+ruby_add_rdepend "
+	dev-ruby/concurrent-ruby:1
+	>=dev-ruby/rack-1:* <dev-ruby/rack-3:*"
+
+ruby_add_bdepend "test? (
+		dev-ruby/json
+		dev-ruby/rack-test
+		=dev-ruby/coffee-script-2*
+		=dev-ruby/execjs-2*
+		=dev-ruby/sass-3* >=dev-ruby/sass-3.1
+		dev-ruby/uglifier
+	)"
+
+all_ruby_prepare() {
+	# Avoid tests for template types that we currently don't package:
+	# eco and ejs.
+	sed -i -e '/eco templates/,/end/ s:^:#:' \
+		-e '/ejs templates/,/end/ s:^:#:' test/test_environment.rb || die
+	sed -i -e '/.ejs/ s:^:#:' test/test_asset.rb || die
+	rm -f test/test_require.rb test/test_{closure,eco,ejs,yui}_{compressor,processor}.rb || die
+	sed -i -e "/bundler/d" Rakefile || die
+}
+
+each_ruby_prepare() {
+	sed -i -e "s:ruby:${RUBY}:" test/test_sprocketize.rb || die
+}
+
+each_ruby_test() {
+	# Make sure we have completely separate copies. Hardlinks won't work
+	# for this test suite.
+	cp -R test test-new || die
+	rm -rf test || die
+	mv test-new test || die
+
+	each_fakegem_test
+}