[gentoo-commits] repo/gentoo:master commit in: dev-python/ply/

["Michał Górny" <mgorny@gentoo.org>]

commit:     de364558acc33c3bc1c37f5c82761d485937ec96
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 10 21:19:38 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 10 21:52:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de364558

dev-python/ply: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ply/ply-3.11-r2.ebuild | 46 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-python/ply/ply-3.11-r2.ebuild b/dev-python/ply/ply-3.11-r2.ebuild
new file mode 100644
index 000000000000..1e825003ff3c
--- /dev/null
+++ b/dev-python/ply/ply-3.11-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Lex-Yacc library"
+HOMEPAGE="
+	http://www.dabeaz.com/ply/
+	https://github.com/dabeaz/ply/
+	https://pypi.org/project/ply/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+
+DOCS=( ANNOUNCE CHANGES TODO )
+
+PATCHES=(
+	"${FILESDIR}/3.6-picklefile-IOError.patch"
+)
+
+python_test() {
+	# Checks for pyc/pyo files
+	local -x PYTHONDONTWRITEBYTECODE=
+
+	cd test || die
+	local t
+	for t in testlex.py testyacc.py; do
+		"${EPYTHON}" "${t}" -v || die "${t} fails with ${EPYTHON}"
+	done
+}
+
+python_install_all() {
+	local HTML_DOCS=( doc/. )
+	use examples && dodoc -r example
+	distutils-r1_python_install_all
+}