[gentoo-commits] repo/gentoo:master commit in: dev-python/build/

["Michał Górny" <mgorny@gentoo.org>]

commit:     96715e7055997890b25b306466007b27a617158d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 10 17:59:51 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 10 18:06:16 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=96715e70

dev-python/build: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/build/build-0.7.0-r1.ebuild | 61 ++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-python/build/build-0.7.0-r1.ebuild b/dev-python/build/build-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..1e9284e7e37e
--- /dev/null
+++ b/dev-python/build/build-0.7.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="A simple, correct PEP517 package builder"
+HOMEPAGE="
+	https://pypi.org/project/build/
+	https://github.com/pypa/build/
+"
+SRC_URI="
+	https://github.com/pypa/build/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-19.0[${PYTHON_USEDEP}]
+	>=dev-python/pep517-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/filelock-3[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
+		>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by the presence of flit_core
+		tests/test_util.py::test_wheel_metadata_isolation
+		# broken by the presence of virtualenv (it changes the error
+		# messages, sic!)
+		tests/test_env.py::test_isolated_env_log
+		tests/test_main.py::test_output_env_subprocess_error
+		'tests/test_main.py::test_output[via-sdist-isolation]'
+		'tests/test_main.py::test_output[wheel-direct-isolation]'
+		# Internet
+		tests/test_main.py::test_build_package
+		tests/test_main.py::test_build_package_via_sdist
+		'tests/test_util.py::test_wheel_metadata[True]'
+		tests/test_util.py::test_with_get_requires
+	)
+
+	epytest -p no:flaky \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}