[gentoo-commits] repo/gentoo:master commit in: dev-libs/xmlsec/

["Sam James" <sam@gentoo.org>]

commit:     e9abfa1dc97206a582cd6e6f07f284f9a1f17dd4
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu May  5 23:11:42 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu May  5 23:11:42 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e9abfa1d

dev-libs/xmlsec: add 1.2.34

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/xmlsec/Manifest             |  1 +
 dev-libs/xmlsec/xmlsec-1.2.34.ebuild | 62 ++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 6b7290a618d7..3aef88c73546 100644
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.33.tar.gz 1991955 BLAKE2B d6bb68ad4ceb936d51165a4ef48824a8cb5d550670ca6015eb9916121555a1a32b3f47774eab1efc2bc5031346f22a0b21115a220dbeb44bba773412f2292bc5 SHA512 6354554b5cdc0a1389f6991efeac919bea912330b36d3be3d3496d61331e9edd2771786d50d2571a439f62ccfc3bd32be0a50bb5a037c4993aac076ad94b46e8
+DIST xmlsec1-1.2.34.tar.gz 1991505 BLAKE2B e86756a07bafb9c64c38934c0b8445b8d775a339b79c6a04e2c944e481174b6b6fc72abacbd48eeb82ad66e2edf868d4ca2180b834a0b585cd8bf98384c02987 SHA512 4e3c17ab71c5ce3c76a80f2077393a5808a537d7eba861bae104c186be57f4be53499b52571913187e0a302962376bc033d7fe8ea769c6a181bf72d3f9eea1f2

diff --git a/dev-libs/xmlsec/xmlsec-1.2.34.ebuild b/dev-libs/xmlsec/xmlsec-1.2.34.ebuild
new file mode 100644
index 000000000000..b63daf1c4d35
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.34.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="https://www.aleksey.com/xmlsec"
+SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+S="${WORKDIR}/${PN}1-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc gcrypt gnutls nss +openssl static-libs test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+	gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4:=
+	>=dev-libs/libxslt-1.0.20:=
+	dev-libs/libltdl
+	gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0= )
+	gnutls? ( >=net-libs/gnutls-2.8.0:= )
+	nss? (
+		>=dev-libs/nspr-4.4.1:=
+		>=dev-libs/nss-3.9:=
+	)
+	openssl? (
+		dev-libs/openssl:0=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	test? (
+		nss? (
+			>=dev-libs/nss-3.9[utils]
+		)
+	)"
+
+src_configure() {
+	# Bash because of bug #721128
+	CONFIG_SHELL="${BROOT}"/bin/bash econf \
+		$(use_enable doc docs) \
+		$(use_enable static-libs static) \
+		$(use_with gcrypt) \
+		$(use_with gnutls) \
+		$(use_with nss nspr) \
+		$(use_with nss) \
+		$(use_with openssl) \
+		--enable-mans \
+		--enable-pkgconfig
+}
+
+src_test() {
+	# See https://github.com/lsh123/xmlsec/issues/280 for TZ=UTC
+	TZ=UTC SHELL="${BROOT}"/bin/bash emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}