[gentoo-commits] repo/gentoo:master commit in: media-radio/tucnak/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     241052b11983a2f2764be9ff8ed8113a2e313f40
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Thu May  5 06:01:14 2022 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Thu May  5 06:03:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=241052b1

media-radio/tucnak: add 4.36

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tucnak/Manifest           |  1 +
 media-radio/tucnak/tucnak-4.36.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index c207b07dc7c0..12eb95a8a852 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.34.tar.gz 3596477 BLAKE2B 530b1e18167e7704b1596dc606f9c352fa761c6e3e060ff88e8dfb744c25faaf0b3840e89d2fad1747cb6dfd688f92222b4553731545d59d00dc8ad01f0c77bf SHA512 860c6887ba004d8efad8d6cd60951f744f772ca4ac6022a7f1b484eb43778eeba8f3426447b9a656dc321816e0b8dfb05906868e6122edaa26a7f3c2679ceb74
+DIST tucnak-4.36.tar.gz 3601081 BLAKE2B 76dfb5a319309203ef452e1e4faff5c47208b5c7f66fb63d9dbf45a6a3a63b35f788d0a05931db44965be6593c5eca1a26c23dcc50e79fd9a70446083f2644b1 SHA512 dee0c6b60ccd66b81257dbc04ead8b9a7df1a77a6c5a73503bcdf8012b8a59318ad8e96ba5a25d6e38ac995312acac23fdf62c5d6d2ad036bc029a691c1a350d

diff --git a/media-radio/tucnak/tucnak-4.36.ebuild b/media-radio/tucnak/tucnak-4.36.ebuild
new file mode 100644
index 000000000000..358be0cafa27
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.36.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}