[gentoo-commits] repo/gentoo:master commit in: dev-java/jackson-dataformat-yaml/

["Florian Schmaus" <flow@gentoo.org>]

commit:     7d402c3ac807ea3664cb59df61f520e3fc12c9f3
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Wed May  4 08:21:29 2022 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Wed May  4 20:03:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7d402c3a

dev-java/jackson-dataformat-yaml: dependency update

Bug: https://bugs.gentoo.org/832694
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 .../jackson-dataformat-yaml-2.13.2-r1.ebuild       | 79 ++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/dev-java/jackson-dataformat-yaml/jackson-dataformat-yaml-2.13.2-r1.ebuild b/dev-java/jackson-dataformat-yaml/jackson-dataformat-yaml-2.13.2-r1.ebuild
new file mode 100644
index 000000000000..139c808cdee6
--- /dev/null
+++ b/dev-java/jackson-dataformat-yaml/jackson-dataformat-yaml-2.13.2-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Skeleton command:
+# java-ebuilder --generate-ebuild --workdir . --pom pom.xml --download-uri https://github.com/FasterXML/jackson-dataformats-text/archive/jackson-dataformats-text-2.13.2.tar.gz --slot 0 --keywords "~amd64 ~arm ~arm64 ~ppc64 ~x86" --ebuild jackson-dataformat-yaml-2.13.2.ebuild
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.13.2"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Support for reading and writing YAML-encoded data via Jackson abstractions"
+HOMEPAGE="https://github.com/FasterXML/jackson-dataformats-text"
+SRC_URI="https://github.com/FasterXML/jackson-dataformats-text/archive/jackson-dataformats-text-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+# Common dependencies
+# POM: pom.xml
+# com.fasterxml.jackson.core:jackson-core:2.13.2 -> >=dev-java/jackson-core-2.13.2:0
+# com.fasterxml.jackson.core:jackson-databind:2.13.2 -> >=dev-java/jackson-databind-2.13.2:0
+# org.yaml:snakeyaml:1.30 -> >=dev-java/snakeyaml-1.30:0
+
+CP_DEPEND="
+	~dev-java/jackson-core-${PV}:0
+	~dev-java/jackson-databind-${PV}.2:0
+	dev-java/snakeyaml:0
+"
+
+DEPEND="
+	>=virtual/jdk-11:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}"
+
+DOCS=( README.md release-notes/{CREDITS,VERSION} )
+
+S="${WORKDIR}/jackson-dataformats-text-jackson-dataformats-text-${PV}/yaml"
+
+JAVA_SRC_DIR=( "src/main/java" "src/moditect" )
+JAVA_RESOURCE_DIRS="src/main/resources"
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="src/test/java"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+JAVA_TEST_EXCLUDES=(
+	# Upstream's usual exclude pattern: "**/failing**/*.java"
+	com.fasterxml.jackson.dataformat.yaml.failing.ObjectIdWithTree2Test
+	com.fasterxml.jackson.dataformat.yaml.failing.PolymorphicWithObjectId25Test
+	com.fasterxml.jackson.dataformat.yaml.failing.SimpleGeneration215Test
+)
+
+src_prepare() {
+	default
+	java-pkg-2_src_prepare
+
+	sed -e 's:@package@:com.fasterxml.jackson.dataformat.yaml:g' \
+		-e "s:@projectversion@:${PV}:g" \
+		-e 's:@projectgroupid@:com.fasterxml.jackson.dataformat:g' \
+		-e "s:@projectartifactid@:${PN}:g" \
+		"${JAVA_SRC_DIR}/com/fasterxml/jackson/dataformat/yaml/PackageVersion.java.in" \
+		> "${JAVA_SRC_DIR}/com/fasterxml/jackson/dataformat/yaml/PackageVersion.java" || die
+
+	# dev-java/snakeyaml-1.30 does not provide module-info
+	sed -e '/snakeyaml;/d' -i src/moditect/module-info.java || die
+}
+
+src_install() {
+	default # https://bugs.gentoo.org/789582
+	java-pkg-simple_src_install
+}