[gentoo-commits] repo/gentoo:master commit in: dev-python/pillow/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8489cd3e715e7c27b7ed8d06b96c57d7bf2f28fa
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May  3 20:01:10 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May  3 20:03:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8489cd3e

dev-python/pillow: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pillow/Manifest               |   1 -
 dev-python/pillow/pillow-9.0.0-r1.ebuild | 107 -------------------------------
 dev-python/pillow/pillow-9.0.0.ebuild    |  98 ----------------------------
 3 files changed, 206 deletions(-)

diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index f5d6c651d20c..6be44f1fc638 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,3 +1,2 @@
-DIST pillow-9.0.0.tar.gz 49510604 BLAKE2B c3b0d07e8fe280e3a253067c4da18ac2dee40d216280632d58ddaa7848e13a165587b9aca61c98f8b5380e53d6d59a4097320bacf6e016e236239af518ec7780 SHA512 d2fd74dd1b8824d994e3767ef9794175dd2f4adc8173612432a3e171705723ee8757d299a87fb1c010b40919792c1ca76578f41977ee3303ccb6f75165deb791
 DIST pillow-9.0.1.tar.gz 49512045 BLAKE2B 14f0969c87c57bad8fc38d873bba7a118d666e8b2e62e777ea17197e5ca973b3994bafb56b4464cde4059f2fc4040d73e7ddeec2a1053aeb1f201bf2ec2b38e2 SHA512 73893fe079bb2405c87b73b13b6eff198fb8970a891a7c9586bd2620ea0310d54cb35b1d594c6c6d3859e47d8d467700f987ae32aa6d3dc4a2e9286e8749869e
 DIST pillow-9.1.0.tar.gz 49748153 BLAKE2B 0051ea9c06c86f004f0708b3aa38f234e9b1fec32ef2ebaddfe47b3717b8ebb4834a2c8c2fe68cfeb44d24abe3a9039732679705f7aec790e62105ac5b51545f SHA512 22ef3a98a36ca8162447b6c716a0a9cff79ae9bf1007b7f835e0a8529fc6a062bea77afff17f444586989fff3e30589a595db34dc78e1e4000b966e8d10172f1

diff --git a/dev-python/pillow/pillow-9.0.0-r1.ebuild b/dev-python/pillow/pillow-9.0.0-r1.ebuild
deleted file mode 100644
index 0dd406cd6c5f..000000000000
--- a/dev-python/pillow/pillow-9.0.0-r1.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-PYTHON_REQ_USE='tk?,threads(+)'
-
-inherit distutils-r1 toolchain-funcs virtualx
-
-MY_PN=Pillow
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Python Imaging Library (fork)"
-HOMEPAGE="https://python-pillow.org/"
-SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="HPND"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
-REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	imagequant? ( media-gfx/libimagequant:0 )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	lcms? ( media-libs/lcms:2= )
-	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
-	truetype? ( media-libs/freetype:2= )
-	webp? ( media-libs/libwebp:0= )
-	xcb? ( x11-libs/libxcb )
-	zlib? ( sys-libs/zlib:0= )"
-RDEPEND="${DEPEND}
-	dev-python/olefile[${PYTHON_USEDEP}]"
-BDEPEND="
-	virtual/pkgconfig
-	test? (
-		${RDEPEND}
-		dev-python/pytest[${PYTHON_USEDEP}]
-		|| (
-			media-gfx/imagemagick[png]
-			media-gfx/graphicsmagick[png]
-		)
-	)
-"
-
-usepil() {
-	usex "${1}" enable disable
-}
-
-python_configure_all() {
-	# It's important that these flags are also passed during the install phase
-	# as well. Make sure of that if you change the lines below. See bug 661308.
-	cat >> setup.cfg <<-EOF || die
-		[build_ext]
-		disable_platform_guessing = True
-		$(usepil truetype)_freetype = True
-		$(usepil jpeg)_jpeg = True
-		$(usepil jpeg2k)_jpeg2000 = True
-		$(usepil lcms)_lcms = True
-		$(usepil tiff)_tiff = True
-		$(usepil imagequant)_imagequant = True
-		$(usepil webp)_webp = True
-		$(usepil webp)_webpmux = True
-		$(usepil xcb)_xcb = True
-		$(usepil zlib)_zlib = True
-	EOF
-
-	# setup.py won't let us add the right toolchain paths but it does
-	# accept additional ones from INCLUDE and LIB so set these. You
-	# wouldn't normally need these at all as the toolchain should look
-	# here anyway but it doesn't for this setup.py.
-	export \
-		INCLUDE="${ESYSROOT}"/usr/include \
-		LIB="${ESYSROOT}"/usr/$(get_libdir)
-
-	# We have patched in this env var.
-	tc-export PKG_CONFIG
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
-	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
-	epytest -p no:relaxed || die "Tests failed with ${EPYTHON}"
-}
-
-python_install() {
-	python_doheader src/libImaging/*.h
-	distutils-r1_python_install
-}
-
-python_install_all() {
-	if use examples ; then
-		docinto example
-		dodoc docs/example/*
-		docompress -x /usr/share/doc/${PF}/example
-	fi
-	distutils-r1_python_install_all
-}

diff --git a/dev-python/pillow/pillow-9.0.0.ebuild b/dev-python/pillow/pillow-9.0.0.ebuild
deleted file mode 100644
index c1fb9e79bab2..000000000000
--- a/dev-python/pillow/pillow-9.0.0.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-PYTHON_REQ_USE='tk?,threads(+)'
-
-inherit distutils-r1 toolchain-funcs virtualx
-
-MY_PN=Pillow
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Python Imaging Library (fork)"
-HOMEPAGE="https://python-pillow.org/"
-SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="HPND"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
-IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
-REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	imagequant? ( media-gfx/libimagequant:0 )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	lcms? ( media-libs/lcms:2= )
-	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
-	truetype? ( media-libs/freetype:2= )
-	webp? ( media-libs/libwebp:0= )
-	xcb? ( x11-libs/libxcb )
-	zlib? ( sys-libs/zlib:0= )"
-RDEPEND="${DEPEND}
-	dev-python/olefile[${PYTHON_USEDEP}]"
-BDEPEND="
-	virtual/pkgconfig
-	test? (
-		${RDEPEND}
-		dev-python/pytest[${PYTHON_USEDEP}]
-		|| (
-			media-gfx/imagemagick[png]
-			media-gfx/graphicsmagick[png]
-		)
-	)
-"
-
-python_configure_all() {
-	# It's important that these flags are also passed during the install phase
-	# as well. Make sure of that if you change the lines below. See bug 661308.
-	DISTUTILS_ARGS=(
-		build_ext
-		--disable-platform-guessing
-		$(use_enable truetype freetype)
-		$(use_enable jpeg)
-		$(use_enable jpeg2k jpeg2000)
-		$(use_enable lcms)
-		$(use_enable tiff)
-		$(use_enable imagequant)
-		$(use_enable webp)
-		$(use_enable webp webpmux)
-		$(use_enable xcb)
-		$(use_enable zlib)
-	)
-
-	# setup.py won't let us add the right toolchain paths but it does
-	# accept additional ones from INCLUDE and LIB so set these. You
-	# wouldn't normally need these at all as the toolchain should look
-	# here anyway but it doesn't for this setup.py.
-	export \
-		INCLUDE="${ESYSROOT}"/usr/include \
-		LIB="${ESYSROOT}"/usr/$(get_libdir)
-
-	# We have patched in this env var.
-	tc-export PKG_CONFIG
-}
-
-python_test() {
-	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
-	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
-	virtx epytest -p no:relaxed
-}
-
-python_install() {
-	python_doheader src/libImaging/*.h
-	distutils-r1_python_install
-}
-
-python_install_all() {
-	if use examples ; then
-		docinto example
-		dodoc docs/example/*
-		docompress -x /usr/share/doc/${PF}/example
-	fi
-	distutils-r1_python_install_all
-}