[gentoo-commits] repo/gentoo:master commit in: app-text/scdoc/

["Sam James" <sam@gentoo.org>]

commit:     569515aaae02628db02e1ba7b81ada12ea2f6cd5
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Tue May  3 17:20:54 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May  3 18:39:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=569515aa

app-text/scdoc: fix incorrect prefix in pc file

* Removal of PREFIX in make all breaks sed'ing @prefix@ leading to
  default value of /usr/local to be used leading to breakage in packages
  that depend on the value being correct to find the scdoc binary.

Closes: https://bugs.gentoo.org/842282
Closes: https://bugs.gentoo.org/842285
Closes: https://bugs.gentoo.org/842288
Closes: https://bugs.gentoo.org/842399
Closes: https://bugs.gentoo.org/842465
Closes: https://bugs.gentoo.org/842402
Closes: https://bugs.gentoo.org/842279
Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/25301
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-text/scdoc/scdoc-1.11.2-r1.ebuild | 45 +++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/app-text/scdoc/scdoc-1.11.2-r1.ebuild b/app-text/scdoc/scdoc-1.11.2-r1.ebuild
new file mode 100644
index 000000000000..c40dcd50d0fa
--- /dev/null
+++ b/app-text/scdoc/scdoc-1.11.2-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Standalone tool for generating man pages with a simple syntax"
+HOMEPAGE="https://git.sr.ht/~sircmpwn/scdoc"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/scdoc"
+	inherit git-r3
+else
+	SRC_URI="https://git.sr.ht/~sircmpwn/scdoc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+src_prepare() {
+	default
+
+	sed -e 's/-Werror//' \
+		-i Makefile || die 'Failed to patch Makefile'
+}
+
+src_compile() {
+	local MY_HS="./scdoc"
+	if tc-is-cross-compiler; then
+		tc-export_build_env
+		MY_HS="./hostscdoc"
+		emake scdoc HOST_SCDOC="./hostscdoc" OUTDIR="${S}/.build.host" CC="$(tc-getBUILD_CC)" \
+			CFLAGS="${BUILD_CFLAGS} -DVERSION='\"${PV}\"'" LDFLAGS="${BUILD_LDFLAGS}"
+		mv scdoc hostscdoc || die 'Failed to rename host scdoc'
+	fi
+
+	emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}" PREFIX="${EPREFIX}/usr" HOST_SCDOC="${MY_HS}"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" PREFIX="${EPREFIX}/usr" HOST_SCDOC="${MY_HS}" \
+		PCDIR="/usr/$(get_libdir)/pkgconfig" install
+}