[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     9cf687644261a6f6b3676e0843ea0e66c9da643f
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 28 15:09:06 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Apr 28 15:31:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9cf68764

gnome-base/gnome-desktop: Version bump to 42.1

* Drop dependence on gtk[X] and xorg-proto. Upstream usage seems to have
  been dropped in 2019 (e.g. commit b8e99fc3 ("gnomebg: remove gdkx/x
  dependency"))

Closes: https://bugs.gentoo.org/834796
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-base/gnome-desktop/Manifest                  |  1 +
 .../gnome-desktop/gnome-desktop-42.1-r300.ebuild   | 80 ++++++++++++++++++++++
 .../gnome-desktop/gnome-desktop-42.1-r400.ebuild   | 73 ++++++++++++++++++++
 3 files changed, 154 insertions(+)

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index aed70403c3ab..046139dad77e 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-desktop-41.3.tar.xz 732804 BLAKE2B 40a88ba4454455f85a46676d4b2f37159617f7eae9d0f5e1a27c3f0ed1e44953ae9475e81558b7cce1b6fd8cd8804cd3f452d060d843d4f58a7af8748b4c35fa SHA512 b02d9fe3bfad56993f9ed7225b38b4b0b685c7ad1480a9d9db5f9a6a8e13c16918d87e6a51160ee3101ab8ce24f4c0632ae351e7bb11cc473523e216ee9cf6bf
 DIST gnome-desktop-42.0.tar.xz 743484 BLAKE2B 7c7d5e74fe01e082c8ec1994bb7666f191e0eed4212c8ef6257ebb4c3e3a5fb95c8a0c47f1c8f0864a36faa239251569e67eafa734cba4a181b6774233352357 SHA512 b9d37765d3cc43bb709e1e9b97deb6ef16d2a8e6ef7cc3c577ba465d4856bbfe8774fb7fc6eaae4d88064081aeeea0c0c77fe2b4ef79b4d9af1232c918526b44
+DIST gnome-desktop-42.1.tar.xz 743032 BLAKE2B 1eda3138e50b0ded50ede12179311ab8888ab0837c650f3e6bad600a4327cdba02b3fbf7cf7ff845669075cbb56b69ca600b8b63b4f05dce93b0a71e76cedbd7 SHA512 a084f705aedf2d159da91dc54f38261760a50e51041321e6a69ee0dff499e11f0a440f5a9582a31977b0270c87e3ba7de0f5c9cc182c0631858afa1d9508ecf4

diff --git a/gnome-base/gnome-desktop/gnome-desktop-42.1-r300.ebuild b/gnome-base/gnome-desktop/gnome-desktop-42.1-r300.ebuild
new file mode 100644
index 000000000000..1c3c7ed2fd59
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-42.1-r300.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/42.0-meson-Add-optionality-for-introspection.patch
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=false
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		-Dgtk_doc=false
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=false
+		-Dlegacy_library=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	rm -r \
+		${ED}/usr/share/gnome/gnome-version.xml \
+		${ED}/usr/share/locale \
+		|| die
+}

diff --git a/gnome-base/gnome-desktop/gnome-desktop-42.1-r400.ebuild b/gnome-base/gnome-desktop/gnome-desktop-42.1-r400.ebuild
new file mode 100644
index 000000000000..4123d7bb7860
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-42.1-r400.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="4/1" # subslot = libgnome-desktop-4 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=gui-libs/gtk-4.4.0:4[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:3
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/42.0-meson-Add-optionality-for-introspection.patch
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=true
+		-Dlegacy_library=false
+	)
+	meson_src_configure
+}