[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog/

["Matt Turner" <mattst88@gentoo.org>]

commit:     e5d451de24b2a2d13226fcea4671f6e9647a1447
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 24 20:34:06 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 24 20:44:41 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5d451de

media-gfx/eog: Version bump to 42.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/eog/Manifest        |  1 +
 media-gfx/eog/eog-42.1.ebuild | 74 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-gfx/eog/Manifest b/media-gfx/eog/Manifest
index 892eb5b2625c..6809fdd6ac3b 100644
--- a/media-gfx/eog/Manifest
+++ b/media-gfx/eog/Manifest
@@ -1,2 +1,3 @@
 DIST eog-41.1.tar.xz 3603320 BLAKE2B 8b0d7affe921bcb2c917f89dc3845360f784b5d5f394a7f94379c98cd905504cde7a8fb6f59aa09bc778e302113ad27ec5815e529b418d68a3012fbf9b018d65 SHA512 0fa514dd6ef195e449bbde183f94850dfca764815a95423376bc0da422d07b6cbd7b35bbdd5ba9d8f995f55aae1e1b65d57626d1809cccf95389767d0ed594e8
 DIST eog-42.0.tar.xz 4446392 BLAKE2B bb89eadaf2066f0ef3b6f99d47d75b438adfd3bca0451e8fa5d4513e98d1e8c6acc518eb7564f2768d43205a56843852edc1aa1ecce9fac8018ae4954376b852 SHA512 3901dbac9a371bac1e1bdc143e3d257a8e25fa2743a97bd9f9ecdb06e43cd5278edf33a46ab24c5e40babef6825181c986c99d9b4fafead71e04f51e65ae2acb
+DIST eog-42.1.tar.xz 4446444 BLAKE2B e500b3f96abfc72f56544c16254a99438137789be771310fd790c201451cf6a56fd9b6efc0ea8466dbb27be57cf0cd146d77c3e4917fda928ca02928ffaddea7 SHA512 12db6bb2218f9dcea0e0558b04c05f3f8eb298eb7170a9511a7996a37082667fe06994d1db3ee4fef759aeb763a9de87749c8defa8d749432b635d2b421d1c8a

diff --git a/media-gfx/eog/eog-42.1.ebuild b/media-gfx/eog/eog-42.1.ebuild
new file mode 100644
index 000000000000..fb9dfdc4d3cc
--- /dev/null
+++ b/media-gfx/eog/eog-42.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome https://gitlab.gnome.org/GNOME/eog"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-42_beta
+	>=x11-misc/shared-mime-info-0.20
+	>=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+	>=x11-libs/gtk+-3.24.15:3[introspection,X]
+	>=gui-libs/libhandy-1.5.0:1
+	sys-libs/zlib
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	lcms? ( media-libs/lcms:2 )
+	xmp? ( media-libs/exempi:2 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	svg? ( >=gnome-base/librsvg-2.44.0:2 )
+
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? (
+		dev-util/gi-docgen
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif libexif)
+		$(meson_use lcms cms)
+		$(meson_use xmp)
+		$(meson_use jpeg libjpeg)
+		$(meson_use svg librsvg)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dinstalled_tests=false
+		-Dlibportal=false # As of 40.3, all libportal usages are flatpak-specific
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}