[gentoo-commits] repo/gentoo:master commit in: gui-libs/gtksourceview/

["Matt Turner" <mattst88@gentoo.org>]

commit:     bd7fe027012873e292ebd7c0ae6993057c6100ff
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 22 04:12:52 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 22 04:17:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bd7fe027

gui-libs/gtksourceview: Version bump to 5.4.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gui-libs/gtksourceview/Manifest                   |  1 +
 gui-libs/gtksourceview/gtksourceview-5.4.1.ebuild | 74 +++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index bbde541af582..c9e10bbbda6a 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1 +1,2 @@
 DIST gtksourceview-5.4.0.tar.xz 1259684 BLAKE2B 1561984d967dc6ab06e02d0da6b0a90573f5bc40670cbc189cef0b56ce7be9f84b0a82ccc2cd73ff3e2fb35218785e183a83a0ad5dd5ba85b023ac221820b88c SHA512 0a84e2012639aa29613896e36bb8e73656661dbd9c045507cae3c0d9863dc1ed0390432091d2d2e62fd4a9a0f1853820a2edb406ef2deecd0996b202c7b741c3
+DIST gtksourceview-5.4.1.tar.xz 1258668 BLAKE2B 588dc30093f9300c96aabdabd5bccc84a4fe93ebdcfab61f72a33113ec3f53826022d730a79e7b467a392d4467a0370b2fd3e6edf5cb2f31525b7c3d18e52107 SHA512 5270db969455ad29498a02a851802228575c9b4b6cf6d4f9736bff95f869f1052550034fe6cc4f0c8d29174559d147068dcd088ab09b2008399f7a717aced298

diff --git a/gui-libs/gtksourceview/gtksourceview-5.4.1.ebuild b/gui-libs/gtksourceview/gtksourceview-5.4.1.ebuild
new file mode 100644
index 000000000000..ab65cf65e059
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.4.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=dev-libs/glib-2.70:2
+	>=gui-libs/gtk-4.5:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}