[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     fb574f55776c6d43897a7a67a6389b3d006b2b3c
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 21 21:25:15 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Thu Apr 21 21:25:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb574f55

app-emulation/86Box: add 3.4

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.4.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest         |  1 +
 2 files changed, 69 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.4.ebuild b/app-emulation/86Box/86Box-3.4.ebuild
new file mode 100644
index 000000000000..9463759e394c
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 1876ad26179d..8043c4dde694 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.3.tar.gz 4017011 BLAKE2B f7d666e8a35cf500309bc02392f170d489c598c957d84a51f63cee870c7d12933c46964b555cf754587b926cfee3f6e99f07518e6c073996933e675b54dcd57e SHA512 c590b138d4cb19519847f13d8d68d6d8a54ee2372cb00e998dbb9b15d6c18beaa2e842625631fa716c1dba49149f1a93e8f6521a02d05d97b91ca311b8d91859
+DIST 86Box-3.4.tar.gz 4218439 BLAKE2B ea5dbc31ca3b801f45c9923d0723fcf7f71dfda2a3835b54ee9c700650f28dbb8ed8644b0344c7cfea244fd755847842466bf203482b5eabde85f72b60b15fd8 SHA512 a60034e027bd188343c8eaefe6c56699bf5f7b8016cb1443b081655377bddbd84159cd63362d268a73fc6a5f92ec38544d2fb82aacdb40e8d0eec83bba00cff0