From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1387684-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 7336D15808D
for <garchives@archives.gentoo.org>; Wed, 20 Apr 2022 09:39:51 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B22A9E0951;
Wed, 20 Apr 2022 09:39:50 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 7D1CDE0951
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Apr 2022 09:39:49 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 6C591341549
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Apr 2022 09:39:48 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 857CB1BD
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Apr 2022 09:39:46 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1650447576.ecdd400028f59f36e1a8680cb2eba032511552ca.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/libinput/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-libs/libinput/Manifest dev-libs/libinput/libinput-1.20.1.ebuild
X-VCS-Directories: dev-libs/libinput/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: ecdd400028f59f36e1a8680cb2eba032511552ca
X-VCS-Branch: master
Date: Wed, 20 Apr 2022 09:39:46 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 4fb60f54-a1e3-4633-a6c9-85b208bf4497
X-Archives-Hash: 3e696b82cb7d5bf81d6693f34ff4cd05
commit: ecdd400028f59f36e1a8680cb2eba032511552ca
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 20 09:38:18 2022 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Apr 20 09:39:36 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ecdd4000
dev-libs/libinput: Bump to version 1.20.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
dev-libs/libinput/Manifest | 1 +
dev-libs/libinput/libinput-1.20.1.ebuild | 88 ++++++++++++++++++++++++++++++++
2 files changed, 89 insertions(+)
diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 4ffa65558dbe..025970ebb5cf 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
DIST libinput-1.19.3.tar.xz 655164 BLAKE2B a07d91603a3d4e759aad25ee46b11dbee47eb013a2361f1b70acd616fee0ed9660e6fa8773948d6acf3686179fd7aaf76bf8285f3dc3137a4b1b605ec0e4d6d2 SHA512 f4b776d0da78c687ba21b430a04941ac6b43f68970c82ec9f7360358fdea5ed6a873948ce66a25bcdd64d4b95fa4bf705cc24dbc25c7c0f5fd2d0efbd763f298
DIST libinput-1.20.0.tar.gz 982547 BLAKE2B 6a30ec5473b7271b89a50cb5147900928bc1ac370cb30bb7a9282517f9ced1973e7f83e864a865c840a1f1fe447459c329b8966211cafcd28f8d1285a36de593 SHA512 b92345809f4e18b2335e3c377d1a8edda523462ff23fba6abcc5f8cf01b80fc4c6e4e06886088788c4b04873d37da210876f201bb81203af2f9f614bc659e6eb
+DIST libinput-1.20.1.tar.gz 983069 BLAKE2B 8e63e286c0c4284f4a61129d8b6394e7ca9f2018c6a2781a7fe4b7389120dcaf5c101ccfb4b0b869afc489999e954ce244213b5d206ff546d698068e738ac853 SHA512 91f6d6957b16d76807b376d4f81333ed16218fd37b090417d03a2e551d1f5b2c734d891d267bcdc4314cd698d7830f2f467389a9af58155e4e97a86002c8db78
diff --git a/dev-libs/libinput/libinput-1.20.1.ebuild b/dev-libs/libinput/libinput-1.20.1.ebuild
new file mode 100644
index 000000000000..c14415db2dff
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.20.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2014-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ virtual/pkgconfig
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/commonmark[${PYTHON_USEDEP}]
+ dev-python/recommonmark[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+ ')
+ >=app-doc/doxygen-1.8.3
+ >=media-gfx/graphviz-2.38.0
+ )
+"
+# test? ( dev-util/valgrind )
+RDEPEND="
+ input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+ >=dev-libs/libevdev-1.9.902
+ >=sys-libs/mtdev-1.1
+ virtual/libudev:=
+ virtual/udev
+"
+DEPEND="${RDEPEND}
+ test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+ has_version -b "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+ has_version -b "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+ has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+ has_version -b ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+ # gui can be built but will not be installed
+ local emesonargs=(
+ -Ddebug-gui=false
+ $(meson_use doc documentation)
+ $(meson_use input_devices_wacom libwacom)
+ $(meson_use test tests)
+ -Dudev-dir="${EPREFIX}$(get_udevdir)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc ; then
+ docinto html
+ dodoc -r "${BUILD_DIR}"/Documentation/.
+ fi
+}
+
+pkg_postinst() {
+ pkgname="dev-python/python-libevdev"
+ if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+ einfo "${pkgname} must be installed to use the"
+ einfo "libinput measure and libinput replay tools."
+ fi
+
+ udevadm hwdb --update --root="${ROOT}"
+}