[gentoo-commits] repo/gentoo:master commit in: media-libs/shaderc/

["Nick Sarnie" <sarnex@gentoo.org>]

commit:     818597b4f9d0639fb366bde9ca8c4a003524caf8
Author:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 19 22:39:52 2022 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Tue Apr 19 22:40:21 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=818597b4

media-libs/shaderc: Rev bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 media-libs/shaderc/shaderc-2022.1-r1.ebuild | 92 +++++++++++++++++++++++++++++
 1 file changed, 92 insertions(+)

diff --git a/media-libs/shaderc/shaderc-2022.1-r1.ebuild b/media-libs/shaderc/shaderc-2022.1-r1.ebuild
new file mode 100644
index 000000000000..3312ef71f4e5
--- /dev/null
+++ b/media-libs/shaderc/shaderc-2022.1-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+CMAKE_ECLASS=cmake
+
+inherit cmake-multilib python-any-r1
+
+DESCRIPTION="Collection of tools, libraries and tests for shader compilation"
+HOMEPAGE="https://github.com/google/shaderc"
+EGIT_COMMIT="${PV}"
+SRC_URI="https://github.com/google/${PN}/archive/v${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-util/glslang-1.3.204[${MULTILIB_USEDEP}]
+	>=dev-util/spirv-tools-1.3.204[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/spirv-headers-1.3.204
+	doc? ( dev-ruby/asciidoctor )
+	test? (
+		dev-cpp/gtest
+		$(python_gen_any_dep 'dev-python/nose[${PYTHON_USEDEP}]')
+	)
+"
+
+PATCHES=(
+		"${FILESDIR}"/${PN}-2020.4-fix-build.patch
+)
+
+# https://github.com/google/shaderc/issues/470
+RESTRICT=test
+
+python_check_deps() {
+	if use test; then
+		has_version --host-root "dev-python/nose[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	cmake_comment_add_subdirectory examples
+
+	# Unbundle glslang, spirv-headers, spirv-tools
+	cmake_comment_add_subdirectory third_party
+	sed -i \
+		-e "s|\$<TARGET_FILE:spirv-dis>|${EPREFIX}/usr/bin/spirv-dis|" \
+		glslc/test/CMakeLists.txt || die
+
+	# Disable git versioning
+	sed -i -e '/build-version/d' glslc/CMakeLists.txt || die
+
+	# Manually create build-version.inc as we disabled git versioning
+	cat <<- EOF > glslc/src/build-version.inc || die
+		"${P}\n"
+		"$(best_version dev-util/spirv-tools)\n"
+		"$(best_version dev-util/glslang)\n"
+	EOF
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DSHADERC_SKIP_TESTS="$(usex !test)"
+		-DSHADERC_ENABLE_WERROR_COMPILE="false"
+	)
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	if multilib_is_native_abi && use doc; then
+		cmake_src_compile glslc_doc_README
+	fi
+	cmake_src_compile
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		use doc && local HTML_DOCS=( "${BUILD_DIR}/glslc/README.html" )
+	fi
+	cmake_src_install
+}