[gentoo-commits] repo/proj/guru:master commit in: sys-cluster/booth/

[gentoo-commits] repo/proj/guru:master commit in: sys-cluster/booth/

[Andrew Ammerlaan]

commit:     47c2d01f64d48bbf219bba4f11654a4cd297d27c
Author:     Andrea Postiglione <andrea.postiglione <AT> gmail <DOT> com>
AuthorDate: Sun Apr 17 19:30:19 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Sun Apr 17 19:30:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=47c2d01f

sys-cluster/booth first release

Signed-off-by: Andrea Postiglione <andrea.postiglione <AT> gmail.com>

 sys-cluster/booth/Manifest                   |  1 +
 sys-cluster/booth/booth-1.0_p20210730.ebuild | 70 ++++++++++++++++++++++++++++
 sys-cluster/booth/metadata.xml               | 19 ++++++++
 3 files changed, 90 insertions(+)

diff --git a/sys-cluster/booth/Manifest b/sys-cluster/booth/Manifest
new file mode 100644
index 000000000..6c4223fa7
--- /dev/null
+++ b/sys-cluster/booth/Manifest
@@ -0,0 +1 @@
+DIST booth-1.0_p20210730.tar.gz 148323 BLAKE2B 5b3594cd64b29131d6e7a7073949c1fa7ff13e76f7ae5e7b5594d212e532979af43fac9affb969ed4a12e92476f32e08250d27fd8fdc303628f7a3dc0520558f SHA512 8a1ef09385b77d89d503325a8edf18a28e75c36e611017993c059258f30bf68b5c48c1685cfcb2a04b2628cffe4682a73750b93cf609fe3317abd7fa4898eb81

diff --git a/sys-cluster/booth/booth-1.0_p20210730.ebuild b/sys-cluster/booth/booth-1.0_p20210730.ebuild
new file mode 100644
index 000000000..bab4d6e6f
--- /dev/null
+++ b/sys-cluster/booth/booth-1.0_p20210730.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools systemd
+
+COMMIT="95d854b32a7cb20cb9a0e90c71d8cc269657304d"
+
+DESCRIPTION="The Booth Cluster Ticket Manager"
+HOMEPAGE="https://github.com/ClusterLabs/booth"
+SRC_URI="https://github.com/ClusterLabs/${PN}/archive/${COMMIT}.tar.gz -> ${PF}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+glue test"
+
+RDEPEND="
+	acct-group/haclient
+	acct-user/hacluster
+	dev-libs/libxml2
+	sys-cluster/pacemaker
+	sys-libs/zlib
+
+	|| (
+		dev-libs/libgcrypt
+		app-crypt/mhash
+	)
+
+	glue? ( sys-cluster/cluster-glue )
+	!glue? (
+		dev-libs/glib
+		sys-apps/systemd
+		sys-cluster/libqb
+	)
+"
+DEPEND="${RDEPEND}"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-coverage
+		--disable-fatal-warnings
+		--enable-user-flags
+
+		--with-initddir="${EPREFIX}/etc/init.d"
+		--with-ocfdir="${EPREFIX}/usr/$(get_libdir)/ocd"
+
+		$(use_with glue)
+		$(use_with test run-build-tests)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	insinto "/usr/$(get_libdir)/firewalld/services"
+	doins contrib/geo-cluster.firewalld.xml
+
+	systemd_dounit conf/booth{@,-arbitrator}.service
+}

diff --git a/sys-cluster/booth/metadata.xml b/sys-cluster/booth/metadata.xml
new file mode 100644
index 000000000..02f63f3f8
--- /dev/null
+++ b/sys-cluster/booth/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email></email>
+    <name></name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">ClusterLabs/booth</remote-id>
+  </upstream>
+  <longdescription lang="en">
+The Booth Cluster Ticket Manager
+Booth manages tickets which authorize cluster sites located in geographically dispersed locations to run resources. It facilitates support of geographically distributed clustering in Pacemaker.
+Booth is based on the Raft consensus algorithm. Though the implementation is not complete (there is no log) and there are a few additions and modifications, booth guarantees that a ticket is always available at just one site as long as it has exclusive control of the tickets.
+  </longdescription>
+  <use>
+    <flag name="glue">Use libraries from <pkg>sys-cluster/cluster-glue</pkg></flag>
+  </use>
+</pkgmetadata>

[gentoo-commits] repo/proj/guru:master commit in: sys-cluster/booth/

[Andrew Ammerlaan]

commit:     4bae54cff1aa98108ca7b6eb712be95708c2a90e
Author:     Andrea Postiglione <andrea.postiglione <AT> gmail <DOT> com>
AuthorDate: Mon Apr 18 11:54:18 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Mon Apr 18 11:54:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=4bae54cf

sys-cluster/booth: added maintainer

Signed-off-by: Andrea Postiglione <andrea.postiglione <AT> gmail.com>

 sys-cluster/booth/metadata.xml | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/sys-cluster/booth/metadata.xml b/sys-cluster/booth/metadata.xml
index 02f63f3f8..1e1f896a1 100644
--- a/sys-cluster/booth/metadata.xml
+++ b/sys-cluster/booth/metadata.xml
@@ -2,8 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <maintainer type="person">
-    <email></email>
-    <name></name>
+    <email>andrea.postiglione@gmail.com</email>
+    <name>Andrea Postiglione</name>
   </maintainer>
   <upstream>
     <remote-id type="github">ClusterLabs/booth</remote-id>