[gentoo-commits] repo/gentoo:master commit in: dev-libs/libelf/

["Sam James" <sam@gentoo.org>]

commit:     0c664d5d9b7423ed8afc82037dddd0dd3bc88553
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 17 15:16:13 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr 17 15:18:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c664d5d

dev-libs/libelf: update EAPI 6 -> 8

Closes: https://bugs.gentoo.org/726968
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libelf/libelf-0.8.13-r3.ebuild | 56 +++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-libs/libelf/libelf-0.8.13-r3.ebuild b/dev-libs/libelf/libelf-0.8.13-r3.ebuild
new file mode 100644
index 000000000000..e048333e06b2
--- /dev/null
+++ b/dev-libs/libelf/libelf-0.8.13-r3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A ELF object file access library"
+HOMEPAGE="http://www.mr511.de/software/"
+SRC_URI="http://www.mr511.de/software/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug nls"
+
+RDEPEND="!dev-libs/elfutils"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+DOCS=( ChangeLog README )
+
+MULTILIB_WRAPPED_HEADERS=( /usr/include/libelf/sys_elf.h )
+
+PATCHES=(
+	"${FILESDIR}/${P}-build.patch"
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# prefix might want to play with this; unfortunately the stupid
+	# macro used to detect whether we're building ELF is so screwed up
+	# that trying to fix it is just a waste of time.
+	export mr_cv_target_elf=yes
+
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable nls) \
+		--enable-shared \
+		$(use_enable debug)
+}
+
+multilib_src_install() {
+	emake \
+		prefix="${ED}/usr" \
+		libdir="${ED}/usr/$(get_libdir)" \
+		install \
+		install-compat \
+		-j1
+
+	find "${D}" -name '*.la' -o -name '*.a' -delete || die
+}