[gentoo-commits] repo/gentoo:master commit in: dev-python/pydevd/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1559d4b195468aeeff35c9a8160be8befdb847be
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 16 16:04:31 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr 16 16:04:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1559d4b1

dev-python/pydevd: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pydevd/Manifest            |  1 -
 dev-python/pydevd/pydevd-2.7.0.ebuild | 88 -----------------------------------
 2 files changed, 89 deletions(-)

diff --git a/dev-python/pydevd/Manifest b/dev-python/pydevd/Manifest
index 1698c91646fb..085e3921ed94 100644
--- a/dev-python/pydevd/Manifest
+++ b/dev-python/pydevd/Manifest
@@ -1,2 +1 @@
-DIST pydev_debugger_2_7_0.tar.gz 4154343 BLAKE2B 6504ffa5eee5548a6aa9e59712b6c0054b69c2e0f6ff48059ed8b2e3edb92ec92ea4e7f9ff084419b46310c4d08f11008571cbf70ccc4efddd0fae688e4110f5 SHA512 8f09b446eeaace1f9ecd3d331813e8bd7d8e09e1fe9dc9fa955ecc26a97ac6015f7becc4005a87405d1154280ec10eb7fa87914bcd41f27e51d90ad3eb99f643
 DIST pydev_debugger_2_8_0.tar.gz 4171117 BLAKE2B 4f0ea0eeb228cb66f71e2046438396ff5ce59b42e620a067bc515ff504fa2da151e05f8ea6cf2d1aaa0768122431ccb45708a88c0616fb2859e96671b172e822 SHA512 b0189f1824b52f8ad35d1d1cfba0bd734806541ae2ff4f410c110763201630d296d10c2b7eaac8c656dfb3ff0f3c31bfdf2de28323778000cc7821e123a877d3

diff --git a/dev-python/pydevd/pydevd-2.7.0.ebuild b/dev-python/pydevd/pydevd-2.7.0.ebuild
deleted file mode 100644
index 6bdca5078bd1..000000000000
--- a/dev-python/pydevd/pydevd-2.7.0.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit distutils-r1 toolchain-funcs
-
-MY_P="pydev_debugger_${PV//./_}"
-
-DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
-HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
-SRC_URI="https://github.com/fabioz/PyDev.Debugger/archive/${MY_P}.tar.gz"
-S="${WORKDIR}/PyDev.Debugger-${MY_P}"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
-
-# After removing and recompiling the prebuilt lib the tests fail?
-# For some reason the test suite is executing a slightly different gdb command
-# then before, which is lacking the file name of the lib that was pre built:
-# gdb: No symbol table is loaded. Use the "file" command
-# This also happens outside of portage so it is not related to any *FLAGS
-RESTRICT="test"
-
-BDEPEND="
-	test? (
-		dev-python/untangle[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-	)
-"
-
-# Block against the version of debugpy that still bundles pydevd
-RDEPEND="
-	!<dev-python/debugpy-1.4.2
-	sys-devel/gdb
-"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# Drop -O3 and -flto compiler args
-	sed -i \
-		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
-		-e '/extra_compile_args/d' \
-		setup.py || die
-
-	# Clean up some prebuilt files
-	rm -r third_party || die
-	cd pydevd_attach_to_process || die
-
-	# Remove these Windows files
-	rm attach_{amd64,x86}.dll || die
-	rm inject_dll_{amd64,x86}.exe || die
-	rm run_code_on_dllmain_{amd64,x86}.dll || die
-	rm -r windows winappdbg || die
-
-	# Remove these MacOS files
-	rm attach_x86_64.dylib || die
-
-	# Remove these prebuilt linux files
-	rm attach_linux_{amd64,x86}.so || die
-
-	cd linux_and_mac || die
-	rm compile_mac.sh || die
-}
-
-src_compile() {
-	pushd pydevd_attach_to_process/linux_and_mac || die
-	# recompile removed file (extracted from compile_linux.sh)
-	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} -o "attach_linux_${ARCH}.so" \
-		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
-	mv "attach_linux_${ARCH}.so" ../ || die
-	popd || die
-	python_foreach_impl distutils-r1_python_compile
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	# Remove this duplicate that is installed directly to /usr/
-	# These files are also correctly installed to the python site-packages dir
-	rm -r "${ED}/usr/pydevd_attach_to_process" || die
-}