[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     5b4a8aa42f396639fe4ce9c9f8aa72a207130ba3
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 15:18:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 16:07:20 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b4a8aa4

dev-python/django: Bump to 4.0.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |   2 +
 dev-python/django/django-4.0.4.ebuild | 109 ++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 71a041cf46b4..9355185ec9b8 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -6,3 +6,5 @@ DIST Django-4.0.2.checksum.txt 2547 BLAKE2B 532139126846e1758bbe7b4dc4ad4aad6c6b
 DIST Django-4.0.2.tar.gz 9996300 BLAKE2B 422b0bb000e7f62a854dc8fa686001acc3f629ded462d2520fad9486a9c8eb5d501d29c6a9f30f63ff8da128ded6f40281439371eb688fb9bc95f2377c5ca0f7 SHA512 c64b25aa69b826805cc7a3efcd63ae41bbc31a61e68cdbda90e6bcec6bd8e2c5fc47b82176d0c1708f55d2c7b082c71939b89cb0621fcf1929d1475e3d393a97
 DIST Django-4.0.3.checksum.txt 2550 BLAKE2B 19471819fb593611217ae13a7dcb6bc67a0323daa94f4a4aeee508305aa09edbbd88ea759968ac989a1971bd72df766c7651e969aa86d3cbddd65b2bb3bf7efa SHA512 573cd0b9291698bf3218d6a77c146b5cda814e99c01cc2c455bf1b5ab2c4cbf4f2f569ea14a108e658237e933a69ec1a5288c293174916f4393ecb119231b9dc
 DIST Django-4.0.3.tar.gz 10061007 BLAKE2B 1cab7d16608acc64b2bd80aeb7d25e740442411080811a2704bbb8ddbc91d86d2aeb761cbb0522a9f095d29468060959ba7f4efd902f6c3afe0f6eb06399dd11 SHA512 4de4445e8b095ad5b858a741adc21939654838ab88b368d532f87490c1c2b3b9c927410f4370e02d2883d51d6a9508f5db3be13c2358221ae687cefea034b294
+DIST Django-4.0.4.checksum.txt 2545 BLAKE2B d82f7b01f49f2b37de3cfd9eb8738e4af69c8eda0c3ed2b6d80a5f876989f36a9335640c5cd5916dcc682fcbf5453c299cb8b3f52e05f2d29413a4c75d274cbc SHA512 9889e086f35192432084fd2ae1104c316e63fa2ab0d34f6954d5eb98b810b5f2e10861a4136c480b54178d2a5453a36f3b893c7720a92f35b44cd578902a8bf9
+DIST Django-4.0.4.tar.gz 10388499 BLAKE2B f839b343bf5c2f83810f2bb22e93a91b18ccc30754589fef2931ebdf29d4600a3bf5493f9e977a3b647097c3a379ea1ef4e0e25366efb54082bc0f43ed00485f SHA512 75ecf5991763237297b458f546d245a25f62272f7013364783aea19469586fa54ce94a16323ac9a6d6b81097f8e962ea7a20f26c7afd8acda842812409215bb1

diff --git a/dev-python/django/django-4.0.4.ebuild b/dev-python/django/django-4.0.4.ebuild
new file mode 100644
index 000000000000..17ed6b3a220c
--- /dev/null
+++ b/dev-python/django/django-4.0.4.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}