[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Maciej Barć]

commit:     7745ad344a4a4e4d369b065f2e700c996c546cb5
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 13:37:36 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 13:40:22 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7745ad34

app-emacs/all-the-icons: bump to 5.0.0_p20220325

2022.03.25 snapshot; this version includes
https://github.com/domtronn/all-the-icons.el/commit/d10cad0b03cf6f38a8035aacd99de005c961744e
and
https://github.com/domtronn/all-the-icons.el/commit/49c7f4dfead067ee9756cc65a6c3d18688eb2cc9
which add Gentoo icons

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/all-the-icons/Manifest                   |  1 +
 .../all-the-icons-5.0.0_p20220325.ebuild           | 44 ++++++++++++++++++++++
 2 files changed, 45 insertions(+)

diff --git a/app-emacs/all-the-icons/Manifest b/app-emacs/all-the-icons/Manifest
index 15ad6fcfb521..3049ed4d9f57 100644
--- a/app-emacs/all-the-icons/Manifest
+++ b/app-emacs/all-the-icons/Manifest
@@ -1 +1,2 @@
 DIST all-the-icons-5.0.0.tar.gz 805496 BLAKE2B c5d81d2ff534bb7ab0000c21fb32107f307d96b1bf09b9227be5900e8160b133cfdc7ea4d4b31a982abb55e29bcf35626af91e3bd9ecbfba00b9b5ed85496a7f SHA512 865db191900dbeb207220df8d91220179dfbbb37e983e9e306ba0a4be576055002beb7335de20327736e8be678056699e8385aa37de766fadc11f4688f99471e
+DIST all-the-icons-5.0.0_p20220325.tar.gz 806105 BLAKE2B bc035ee726bf1d2f9839231ddd3bbaaca93b76c30026a3fcef4579f28f7f9677b37fa8b2652e82ae710f23272b56c884cb9454d54d8c2962f20e0fe9cf3c0bdd SHA512 3e45f208b46e7b1b596b6beb41cc11145db49e3e60e7a42593db94000f226e197b30580ba46d490b456f90349e7db2e49027a572b90f32048bcf0e68af9f22bf

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild
new file mode 100644
index 000000000000..cf28205eb9e6
--- /dev/null
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+H=65c496d3d1d1298345beb9845840067bffb2ffd8
+NEED_EMACS=24.3
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="Various icon fonts propertized for Emacs"
+HOMEPAGE="https://github.com/domtronn/all-the-icons.el/"
+SRC_URI="https://github.com/domtronn/${PN}.el/archive/${H}.tar.gz
+			-> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}.el-${H}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( app-emacs/f )"
+
+DOC_CONTENTS="You may need to install the required fonts by executing
+	the \"all-the-icons-install-fonts\" function."
+DOCS=( README.md logo.png )
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	elisp_src_compile
+	elisp-compile data/*.el
+}
+
+src_test() {
+	${EMACS} ${EMACSFLAGS} ${BYTECOMPFLAGS} \
+			 -L . -L data -L test -l test/all-the-icons-test.el \
+			 -f ert-run-tests-batch-and-exit || die "tests failed"
+}
+
+src_install() {
+	elisp_src_install
+	elisp-install ${PN}/data data/*.el{,c}
+}

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Maciej Barć]

commit:     0dfa7da035391fe699303acefb2c1d0da3a9b621
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon May  9 22:38:06 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon May  9 22:38:26 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0dfa7da0

app-emacs/all-the-icons: install the "all-the-icons" ttf font

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 ...-5.0.0.ebuild => all-the-icons-5.0.0-r1.ebuild} | 28 +++++++++++++++++++++-
 ...ild => all-the-icons-5.0.0_p20220325-r1.ebuild} | 28 +++++++++++++++++++++-
 2 files changed, 54 insertions(+), 2 deletions(-)

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0-r1.ebuild
similarity index 62%
rename from app-emacs/all-the-icons/all-the-icons-5.0.0.ebuild
rename to app-emacs/all-the-icons/all-the-icons-5.0.0-r1.ebuild
index cb1873d52bb6..1caaee0f131f 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0-r1.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 NEED_EMACS=24.3
 
-inherit elisp readme.gentoo-r1
+inherit elisp font readme.gentoo-r1
 
 DESCRIPTION="Various icon fonts propertized for Emacs"
 HOMEPAGE="https://github.com/domtronn/all-the-icons.el/"
@@ -26,6 +26,11 @@ DOC_CONTENTS="You may need to install the required fonts by executing
 DOCS=( README.md logo.png )
 SITEFILE="50${PN}-gentoo.el"
 
+pkg_setup() {
+	elisp_pkg_setup
+	font_pkg_setup
+}
+
 src_compile() {
 	elisp_src_compile
 	elisp-compile data/*.el
@@ -40,4 +45,25 @@ src_test() {
 src_install() {
 	elisp_src_install
 	elisp-install ${PN}/data data/*.el{,c}
+
+	# Install all-the-icons.ttf, special font made explicitly for this library.
+	# NOTICE: "fonts" directory also contains some bundled fonts,
+	# that is why we need this small re-implementation of font eclass,
+	# to suit this specific use case.
+	pushd "${S}"/fonts >/dev/null || die
+	insinto ${FONTDIR}
+	doins ${PN}.ttf
+	font_xfont_config
+	font_fontconfig
+	popd >/dev/null || die
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+	font_pkg_postinst
+}
+
+pkg_postrm() {
+	elisp_pkg_postrm
+	font_pkg_postrm
 }

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
similarity index 63%
rename from app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild
rename to app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
index cf28205eb9e6..029e12f0222a 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
@@ -6,7 +6,7 @@ EAPI=8
 H=65c496d3d1d1298345beb9845840067bffb2ffd8
 NEED_EMACS=24.3
 
-inherit elisp readme.gentoo-r1
+inherit elisp font readme.gentoo-r1
 
 DESCRIPTION="Various icon fonts propertized for Emacs"
 HOMEPAGE="https://github.com/domtronn/all-the-icons.el/"
@@ -27,6 +27,11 @@ DOC_CONTENTS="You may need to install the required fonts by executing
 DOCS=( README.md logo.png )
 SITEFILE="50${PN}-gentoo.el"
 
+pkg_setup() {
+	elisp_pkg_setup
+	font_pkg_setup
+}
+
 src_compile() {
 	elisp_src_compile
 	elisp-compile data/*.el
@@ -41,4 +46,25 @@ src_test() {
 src_install() {
 	elisp_src_install
 	elisp-install ${PN}/data data/*.el{,c}
+
+	# Install all-the-icons.ttf, special font made explicitly for this library.
+	# NOTICE: "fonts" directory also contains some bundled fonts,
+	# that is why we need this small re-implementation of font eclass,
+	# to suit this specific use case.
+	pushd "${S}"/fonts >/dev/null || die
+	insinto ${FONTDIR}
+	doins ${PN}.ttf
+	font_xfont_config
+	font_fontconfig
+	popd >/dev/null || die
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+	font_pkg_postinst
+}
+
+pkg_postrm() {
+	elisp_pkg_postrm
+	font_pkg_postrm
 }

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Arthur Zamarin]

commit:     5913234e451dddf1edfe8f5160332dec27f95b6f
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 27 17:35:36 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 27 17:35:36 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5913234e

app-emacs/all-the-icons: Stabilize 5.0.0_p20220325-r1 amd64, #892231

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
index 029e12f0222a..bee0fc32de73 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,7 +16,7 @@ S="${WORKDIR}"/${PN}.el-${H}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Maciej Barć]

commit:     a77489710007822d996779e7e9b1caffa6ab899d
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 30 16:53:29 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Jan 30 17:00:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7748971

app-emacs/all-the-icons: set H for correct PV; format

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 .../all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild      | 10 +++++-----
 1 file changed, 5 insertions(+), 5 deletions(-)

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
index bee0fc32de73..14dc94b6fbe9 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20220325-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-H=65c496d3d1d1298345beb9845840067bffb2ffd8
+[[ ${PV} == *_p20220325 ]] && H=65c496d3d1d1298345beb9845840067bffb2ffd8
 NEED_EMACS=24.3
 
 inherit elisp font readme.gentoo-r1
@@ -11,7 +11,7 @@ inherit elisp font readme.gentoo-r1
 DESCRIPTION="Various icon fonts propertized for Emacs"
 HOMEPAGE="https://github.com/domtronn/all-the-icons.el/"
 SRC_URI="https://github.com/domtronn/${PN}.el/archive/${H}.tar.gz
-			-> ${P}.tar.gz"
+	-> ${P}.tar.gz"
 S="${WORKDIR}"/${PN}.el-${H}
 
 LICENSE="MIT"
@@ -38,9 +38,9 @@ src_compile() {
 }
 
 src_test() {
-	${EMACS} ${EMACSFLAGS} ${BYTECOMPFLAGS} \
-			 -L . -L data -L test -l test/all-the-icons-test.el \
-			 -f ert-run-tests-batch-and-exit || die "tests failed"
+	${EMACS} ${EMACSFLAGS} ${BYTECOMPFLAGS}                     \
+		-L . -L data -L test -l test/all-the-icons-test.el      \
+		-f ert-run-tests-batch-and-exit || die "tests failed"
 }
 
 src_install() {

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Maciej Barć]

commit:     e34155ed9f521e0956a94b9d2fb52ded88b55475
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  2 23:49:51 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sun Apr  2 23:49:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e34155ed

app-emacs/all-the-icons: bump to 5.0.0_p20230316

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/all-the-icons/Manifest                   |  1 +
 .../all-the-icons-5.0.0_p20230316.ebuild           | 80 ++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/app-emacs/all-the-icons/Manifest b/app-emacs/all-the-icons/Manifest
index 3049ed4d9f57..8beda625e264 100644
--- a/app-emacs/all-the-icons/Manifest
+++ b/app-emacs/all-the-icons/Manifest
@@ -1,2 +1,3 @@
 DIST all-the-icons-5.0.0.tar.gz 805496 BLAKE2B c5d81d2ff534bb7ab0000c21fb32107f307d96b1bf09b9227be5900e8160b133cfdc7ea4d4b31a982abb55e29bcf35626af91e3bd9ecbfba00b9b5ed85496a7f SHA512 865db191900dbeb207220df8d91220179dfbbb37e983e9e306ba0a4be576055002beb7335de20327736e8be678056699e8385aa37de766fadc11f4688f99471e
 DIST all-the-icons-5.0.0_p20220325.tar.gz 806105 BLAKE2B bc035ee726bf1d2f9839231ddd3bbaaca93b76c30026a3fcef4579f28f7f9677b37fa8b2652e82ae710f23272b56c884cb9454d54d8c2962f20e0fe9cf3c0bdd SHA512 3e45f208b46e7b1b596b6beb41cc11145db49e3e60e7a42593db94000f226e197b30580ba46d490b456f90349e7db2e49027a572b90f32048bcf0e68af9f22bf
+DIST all-the-icons-5.0.0_p20230316.tar.gz 807075 BLAKE2B 29ca4c92a61894eab422548de0be3375de866115d95c76c4cf92a1570df0ec5ed67a74fdcd6bf365660a08300aead96efed3d0282966373543d09f2bc775a599 SHA512 160d727233e7cccffcf8a020968f9294f0574ee1267b66565991f46abaaf10c4582bb543f01bdf4f4ab5fc15aee8e2414db785370d13dcd6ca84ad819964696b

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
new file mode 100644
index 000000000000..c75ee6389247
--- /dev/null
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp font readme.gentoo-r1
+
+DESCRIPTION="Various icon fonts propertized for Emacs"
+HOMEPAGE="https://github.com/domtronn/all-the-icons.el/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/domtronn/${PN}.el.git"
+else
+	if [[ ${PV} == *_p20230316 ]] ; then
+		COMMIT=d922aff57ac8308d3ed067f9151cc76d342855f2
+		SRC_URI="https://github.com/domtronn/${PN}.el/archive/${COMMIT}.tar.gz
+			-> ${P}.tar.gz"
+		S="${WORKDIR}"/${PN}.el-${COMMIT}
+	else
+		SRC_URI="https://github.com/domtronn/${PN}.el/archive/${PV}.tar.gz
+			-> ${P}.tar.gz"
+		S="${WORKDIR}"/${PN}.el-${PV}
+	fi
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( app-emacs/f )"
+
+DOC_CONTENTS="You may need to install the required fonts by executing
+	the \"all-the-icons-install-fonts\" function."
+DOCS=( README.md logo.png )
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+	elisp_pkg_setup
+	font_pkg_setup
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-compile data/*.el
+}
+
+src_test() {
+	${EMACS} ${EMACSFLAGS} ${BYTECOMPFLAGS}                     \
+		-L . -L data -L test -l test/all-the-icons-test.el      \
+		-f ert-run-tests-batch-and-exit || die "tests failed"
+}
+
+src_install() {
+	elisp_src_install
+	elisp-install ${PN}/data data/*.el{,c}
+
+	# Install all-the-icons.ttf, special font made explicitly for this library.
+	# NOTICE: "fonts" directory also contains some bundled fonts,
+	# that is why we need this small re-implementation of font eclass,
+	# to suit this specific use case.
+	pushd "${S}"/fonts >/dev/null || die
+	insinto ${FONTDIR}
+	doins ${PN}.ttf
+	font_xfont_config
+	font_fontconfig
+	popd >/dev/null || die
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+	font_pkg_postinst
+}
+
+pkg_postrm() {
+	elisp_pkg_postrm
+	font_pkg_postrm
+}

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Arthur Zamarin]

commit:     8545a5dff2375dd4635b5b8e724c8996d96d7343
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue May  9 04:08:42 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue May  9 04:08:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8545a5df

app-emacs/all-the-icons: Stabilize 5.0.0_p20230316 amd64, #905966

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
index c75ee6389247..e502ad6045f9 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
@@ -22,7 +22,7 @@ else
 			-> ${P}.tar.gz"
 		S="${WORKDIR}"/${PN}.el-${PV}
 	fi
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="amd64 ~x86"
 fi
 
 LICENSE="MIT"

[gentoo-commits] repo/gentoo:master commit in: app-emacs/all-the-icons/

[Maciej Barć]

commit:     1da0143e8b07d65dff167f96988a0c54d494c829
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 12 20:30:18 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sat Aug 12 23:23:15 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1da0143e

app-emacs/all-the-icons: disable tests

Closes: https://bugs.gentoo.org/911260
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
index e502ad6045f9..2854c3f562fd 100644
--- a/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
+++ b/app-emacs/all-the-icons/all-the-icons-5.0.0_p20230316.ebuild
@@ -28,7 +28,7 @@ fi
 LICENSE="MIT"
 SLOT="0"
 IUSE="test"
-RESTRICT="!test? ( test )"
+RESTRICT="test"  # Autogenerated tests cause function redefinitions
 
 BDEPEND="test? ( app-emacs/f )"