[gentoo-commits] repo/gentoo:master commit in: net-vpn/networkmanager-openconnect/

["Matt Turner" <mattst88@gentoo.org>]

commit:     1ae6507aed3ee14db4887f62b6f873a079f487db
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  8 20:19:44 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr  8 21:20:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ae6507a

net-vpn/networkmanager-openconnect: Version bump to 1.2.8

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-vpn/networkmanager-openconnect/Manifest        |  1 +
 .../networkmanager-openconnect-1.2.8.ebuild        | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/net-vpn/networkmanager-openconnect/Manifest b/net-vpn/networkmanager-openconnect/Manifest
index f4c968f2305c..5900b7435676 100644
--- a/net-vpn/networkmanager-openconnect/Manifest
+++ b/net-vpn/networkmanager-openconnect/Manifest
@@ -1 +1,2 @@
 DIST NetworkManager-openconnect-1.2.6.tar.xz 713464 BLAKE2B 7837d2e825b8e962a960bfd00d3e9a9ed247d20d3628d8242c86cb145f8aa3fa8e748126785f067f348a661867436fa5f6e529e4dfefdcb07eec273a807206b0 SHA512 8e6f0af6bcc275d5afff6388b75700c35a5b65773118876203a30ad42a5758cef5d27af8954e8c47bdc46c2b5dfd70262d894aca3d3a62bcab6d240c03eb6fb2
+DIST NetworkManager-openconnect-1.2.8.tar.xz 857808 BLAKE2B b9dd1f75eb34b3149b1d8520fa34caec9547c581affd8065116376f5ee9b0332dc8791af63a88b918445b17b9fd5655b5c154a32c150da62a015ae94221c4634 SHA512 5209fb15ce22511f9b9ccde5e19c86136c3236490c4793afcc2d4081ad87dc4c5fde7f6335db1f50cbbb674b1afc7c42a8c89a6d046ba3945691b2dfb3691d38

diff --git a/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.8.ebuild b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.8.ebuild
new file mode 100644
index 000000000000..145fe1c4dd0c
--- /dev/null
+++ b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager OpenConnect plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager https://gitlab.gnome.org/GNOME/NetworkManager-openconnect"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="gtk"
+
+DEPEND="
+	>=net-misc/networkmanager-1.2:=
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/dbus-glib-0.74
+	dev-libs/libxml2:2
+	>=net-vpn/openconnect-3.02:=
+	gtk? (
+		>=app-crypt/libsecret-0.18
+
+		>=app-crypt/gcr-3.4:=
+		>=x11-libs/gtk+-3.12:3
+
+		>=gui-libs/gtk-4.0:4
+		>=net-libs/libnma-1.8.36
+	)
+"
+
+RDEPEND="
+	${DEPEND}
+	acct-group/nm-openconnect
+	acct-user/nm-openconnect
+"
+
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Bug #830257
+	sed -i 's|/appdata|/metainfo|g' Makefile.{in,am} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--disable-static \
+		--without-libnm-glib \
+		$(use_with gtk gnome) \
+		$(use_with gtk authdlg) \
+		$(use_with gtk gtk4)
+}