[gentoo-commits] repo/gentoo:master commit in: dev-python/libcloud/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0f76d16c602cddc7d9c65ffb5761a804ecaad921
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 31 11:01:23 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 31 11:33:00 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f76d16c

dev-python/libcloud: Bump to 3.5.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/libcloud/Manifest              |  1 +
 dev-python/libcloud/libcloud-3.5.1.ebuild | 61 +++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/libcloud/Manifest b/dev-python/libcloud/Manifest
index 5efb0c8bd662..4b597387da28 100644
--- a/dev-python/libcloud/Manifest
+++ b/dev-python/libcloud/Manifest
@@ -1 +1,2 @@
 DIST apache-libcloud-3.4.1.tar.bz2 1851322 BLAKE2B f141b85423babc41c4dc61f4ef27228da10f2d6d7c9a0dfff0a292cc226a36a7626f8398a8e04202417955720ea5eb0b48736b704cc1379ab05a2bc4e3e0c86e SHA512 72a745a689229901277b347a45e86c6b66836b490d177bfa078062f54d28a149da158b8224b7c8ad6c278de18ed87b2d22bcc119f2577159ef5ecc3fa1ec621f
+DIST apache-libcloud-3.5.1.tar.bz2 1859270 BLAKE2B c2e49a79ac4feccb5285d9bf55a4a6e8486d32968216b68e8c8f5b049ef5fa8caae853b4e4cc31ec2c323aedf3de275ab79758b1a055d7f20bbde994c58ba882 SHA512 22d6facf344687bfcfd32e53ede12227882f55bf54ffcf75d5584652c4cd257905c56e359d9c6b050635faa2305c344a6dfdc17007eb41143ccff772bd31d91e

diff --git a/dev-python/libcloud/libcloud-3.5.1.ebuild b/dev-python/libcloud/libcloud-3.5.1.ebuild
new file mode 100644
index 000000000000..954153c4156f
--- /dev/null
+++ b/dev-python/libcloud/libcloud-3.5.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="https://libcloud.apache.org/"
+SRC_URI="mirror://apache/${PN}/apache-${P}.tar.bz2"
+S="${WORKDIR}/apache-${P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-2.6.1[${PYTHON_USEDEP}]
+		dev-python/lockfile[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Needs network access
+	libcloud/test/compute/test_ovh.py::OvhTests::test_list_nodes_invalid_region
+	libcloud/test/test_connection.py::BaseConnectionClassTestCase::test_connection_timeout_raised
+	libcloud/test/test_connection.py::ConnectionClassTestCase::test_retry_on_all_default_retry_exception_classes
+	# TODO
+	libcloud/test/compute/test_ssh_client.py::ParamikoSSHClientTests::test_key_file_non_pem_format_error
+)
+
+src_prepare() {
+	if use examples; then
+		mkdir examples || die
+		mv example_*.py examples || die
+	fi
+
+	# needed for tests
+	cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	use examples && dodoc -r examples
+	distutils-r1_src_install
+}