[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-shell-extension-gsconnect/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     3e61b88d7f5a9624a951a9a9f0cdc51139625281
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 27 09:16:18 2022 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Mar 27 09:16:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e61b88d

gnome-extra/gnome-shell-extension-gsconnect: add 49

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../gnome-shell-extension-gsconnect/Manifest       |  1 +
 .../gnome-shell-extension-gsconnect-49.ebuild      | 68 ++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index bb068ebc4f46..90f6b9571e12 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-48.tar.gz 795292 BLAKE2B d7885d5a29c2a71d5180baed0da201b921ea9058c284b110becbc84594610f6b5ffd539b598c091113f3ad2e12f9adb486d216d4b37064ef1b6218edc547ec82 SHA512 309e4fdb3f13d4c14f744316f7904aa7c4d5c2c712187625ac1db6de7f1a03fe156754468ba4b982ebed9042006701c3f7eb7114d1e84a7051332edf58c5b21b
+DIST gnome-shell-extension-gsconnect-49.tar.gz 852895 BLAKE2B 21822c3bd724638be0ee537c5cfe86deda9e68fccc58d4f84ad8981d98e42ffc35c9065e9a8cb64baa07e9eea647439bbbdd01d2985c20d2e940cfa3238fe536 SHA512 35da54b9603adefb2dd42e2af3037c414565ab5e936f24180a193c9378ec9e9c0ae02663048679a29385a57050ebe93838fe45190444c41f82cd571ac1a39b52

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-49.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-49.ebuild
new file mode 100644
index 000000000000..02be1761f68f
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-49.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils meson readme.gentoo-r1 xdg
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.68
+	=gnome-base/gnome-shell-41*
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dinstalled_tests=false \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}