[gentoo-commits] repo/gentoo:master commit in: dev-libs/jsonrpc-glib/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3d01869cd6c9597082535f0db9e5925ad59e2260
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 22 01:48:41 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Mar 22 02:46:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d01869c

dev-libs/jsonrpc-glib: Version bump to 3.42.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/jsonrpc-glib/Manifest                   |  1 +
 dev-libs/jsonrpc-glib/jsonrpc-glib-3.42.0.ebuild | 58 ++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-libs/jsonrpc-glib/Manifest b/dev-libs/jsonrpc-glib/Manifest
index 0137d1391f72..b65e65dfe7ba 100644
--- a/dev-libs/jsonrpc-glib/Manifest
+++ b/dev-libs/jsonrpc-glib/Manifest
@@ -1 +1,2 @@
 DIST jsonrpc-glib-3.40.0.tar.xz 42392 BLAKE2B 106d010d5615d6c4a3e1fdc314d1d63be0b76424aca4c6e3771c21e75b79dca5f524e711c99fe1175797644e11d0458317bfa1f363a5abd296dab5b3f95dd708 SHA512 5d4fae86e7eeb029a8daf3eff26107a374ba1b68caa2862563e8d9854913ae306448f4c712be6f0f82961031f1b618aaba7ded154f81b4a023fa366c71f1b887
+DIST jsonrpc-glib-3.42.0.tar.xz 42420 BLAKE2B a60ebebfee652ea694cd2884e057522534826cbca506d04847d29a23dd3035e9a1043912c9a434d4b8b58a6fcb91ba05cc8c76cf380e6205f3d89f9387800bf6 SHA512 615e446dba2b1bbefe1bf8891449de9d39e3486fefda590781f59469ea50e6affa487bcb260bd3e21ca30e696b1dec7a761c8d93ec9c0894d9bb4c3d65f106dc

diff --git a/dev-libs/jsonrpc-glib/jsonrpc-glib-3.42.0.ebuild b/dev-libs/jsonrpc-glib/jsonrpc-glib-3.42.0.ebuild
new file mode 100644
index 000000000000..9285abade7fb
--- /dev/null
+++ b/dev-libs/jsonrpc-glib/jsonrpc-glib-3.42.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala
+
+DESCRIPTION="JSON-RPC library for GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/jsonrpc-glib"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="gtk-doc +introspection test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_profiling=false # -pg passing
+		$(meson_use introspection with_introspection)
+		$(meson_use vala with_vapi)
+		$(meson_use gtk-doc enable_gtk_doc)
+		$(meson_use test enable_tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}