[gentoo-commits] repo/gentoo:master commit in: dev-ruby/slim/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     efca8b63e6f710b4828749c7910b91a24e12d7b5
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 20 09:33:11 2022 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun Mar 20 10:04:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=efca8b63

dev-ruby/slim: add ruby30; EAPI 8

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/slim/slim-4.1.0-r2.ebuild | 55 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-ruby/slim/slim-4.1.0-r2.ebuild b/dev-ruby/slim/slim-4.1.0-r2.ebuild
new file mode 100644
index 000000000000..5ff227866234
--- /dev/null
+++ b/dev-ruby/slim/slim-4.1.0-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGES README.md"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_RECIPE_DOC="rake"
+RUBY_FAKEGEM_TASK_DOC="yard"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A template language aiming to reduce the syntax to the essential parts"
+HOMEPAGE="http://slim-lang.com/"
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+SLOT="$(ver_cut 1)"
+IUSE="doc"
+
+ruby_add_rdepend ">=dev-ruby/tilt-2.0.6:* =dev-ruby/tilt-2.0*:*
+	>=dev-ruby/temple-0.7.6:0.7
+	!!<dev-ruby/slim-3.0.9-r1"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard dev-ruby/redcarpet )"
+
+ruby_add_bdepend "test? ( dev-ruby/redcarpet dev-ruby/sassc )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# This sinatra code expects tests to be installed but we strip those.
+	sed -i -e "s/require 'sinatra'/require 'bogussinatra'/" Rakefile || die
+
+	# Add missing include, bug 816573
+	sed -i -e "1irequire 'ostruct'" test/core/test_code_evaluation.rb || die
+
+	# Avoid tests for things we don't have. The builder test does not pass with tilt 2.x
+	sed -i -e '/test_wip_render_with_asciidoc/,/^  end/ s:^:#:' \
+		-e '/test_render_with_wiki/,/^  end/ s:^:#:' \
+		-e '/test_render_with_creole/,/^  end/ s:^:#:' \
+		-e '/test_render_with_builder/,/^  end/ s:^:#:' \
+		-e '/test_render_with_org/,/^  end/ s:^:#:' test/core/test_embedded_engines.rb || die
+
+	sed -i -e '/s\.files/ s/git ls-files/find . -type f -print/' \
+		-e '/s\.executables/ s:git ls-files -- bin/\*:find bin -type f -print:' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_prepare() {
+	sed -i -e '/Open3/ s:ruby:'${RUBY}':' test/core/test_commands.rb || die
+}