[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     45a07b0a3e00e434f8c5b76b137bd8039ad4c56b
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 19 13:52:46 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Mar 19 15:21:20 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45a07b0a

app-emulation/86Box: add 3.3

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.3.ebuild | 66 ++++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest         |  1 +
 2 files changed, 67 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.3.ebuild b/app-emulation/86Box/86Box-3.3.ebuild
new file mode 100644
index 000000000000..8408b5693b27
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 690f4082021c..6a88968f35fd 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.2.1.tar.gz 3967126 BLAKE2B 0979fc9e87da17f452022a4a1484da72eb0091835c4d7ed225e1e70940e5f7399b7b7cb22816419dbfd040a72ec2a6e50ae0eddc81cad6ef75974f4d511f9f3b SHA512 d725b9c2d2ada47e4492dd09c79af15010a03b174cf99705cf7ffbd4de39aa3a745bf5ab41e4f173e89f4c8d9c130e7540014a1824ff34bb88e634d8dc7860eb
+DIST 86Box-3.3.tar.gz 4017011 BLAKE2B f7d666e8a35cf500309bc02392f170d489c598c957d84a51f63cee870c7d12933c46964b555cf754587b926cfee3f6e99f07518e6c073996933e675b54dcd57e SHA512 c590b138d4cb19519847f13d8d68d6d8a54ee2372cb00e998dbb9b15d6c18beaa2e842625631fa716c1dba49149f1a93e8f6521a02d05d97b91ca311b8d91859