[gentoo-commits] repo/gentoo:master commit in: dev-libs/cereal/

["Dennis Lamm" <expeditioneer@gentoo.org>]

commit:     fcb788f36a5016050159c218c96524e2673d3d66
Author:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 18 16:36:23 2022 +0000
Commit:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
CommitDate: Fri Mar 18 17:04:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fcb788f3

dev-libs/cereal: unbundle rapidjson

Bug: https://bugs.gentoo.org/792444
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>

 dev-libs/cereal/cereal-1.3.2-r1.ebuild | 45 ++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-libs/cereal/cereal-1.3.2-r1.ebuild b/dev-libs/cereal/cereal-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..3a40d8fa882d
--- /dev/null
+++ b/dev-libs/cereal/cereal-1.3.2-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Header-only C++11 serialization library"
+HOMEPAGE="https://uscilab.github.io/cereal/"
+SRC_URI="https://github.com/USCiLab/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="dev-libs/rapidjson"
+
+src_prepare() {
+	if ! use doc ; then
+		sed -i -e '/add_subdirectory(doc/d' CMakeLists.txt || die
+	fi
+
+	# remove bundled rapidjson
+	rm -r include/cereal/external/rapidjson || die 'could not remove bundled rapidjson'
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# TODO: drop bundled doctest, rapidxml (bug #792444)
+
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+
+		# Avoid Boost dependency
+		-DSKIP_PERFORMANCE_COMPARISON=ON
+
+		-DWITH_WERROR=OFF
+	)
+
+	cmake_src_configure
+}