[gentoo-commits] repo/gentoo:master commit in: x11-libs/libva/

["Matt Turner" <mattst88@gentoo.org>]

commit:     9e54154f262abcca950ab650aec6c71e600f7808
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 17 04:23:14 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Mar 17 04:28:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e54154f

x11-libs/libva: Version bump to 2.14.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 x11-libs/libva/Manifest            |  1 +
 x11-libs/libva/libva-2.14.0.ebuild | 68 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/x11-libs/libva/Manifest b/x11-libs/libva/Manifest
index dd28070f7744..d05aac89f2b9 100644
--- a/x11-libs/libva/Manifest
+++ b/x11-libs/libva/Manifest
@@ -1 +1,2 @@
 DIST libva-2.13.0.tar.gz 256724 BLAKE2B 97dd51bf488dc88027125973399e17dedcce03b7bf5104fd9bf17156c5013e1e9d46f2bf78c16431141294f75549a00fed3542b4f79dd31b032f4505c11d07d7 SHA512 226d09956754c9942348ed289f210268bad64dbba95d948b33ae063f7ecb276af9da083a48c03c3c79ad4305716d203898bc75a109945d064a5fe6fb43398dea
+DIST libva-2.14.0.tar.gz 266254 BLAKE2B 1ad504dc7f72b15bb35b486a5fcb327c14663b80068791aa983f2d46876b1504b8330888430b85d2fb309bd5aa2a11c4a34589b68fa140e10b27cb952e3eb5c7 SHA512 8d87b49c7242174d05dca709bd79e6e45cea6e6060d12f5cf7636433be587c2b3a6c3183f632fb0ff49b19f31f915a2a62818c26f57c3a8f40741aa1ab8270b4

diff --git a/x11-libs/libva/libva-2.14.0.ebuild b/x11-libs/libva/libva-2.14.0.ebuild
new file mode 100644
index 000000000000..2524e763954e
--- /dev/null
+++ b/x11-libs/libva/libva-2.14.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson-multilib optfeature
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm wayland X"
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	wayland? ( dev-util/wayland-scanner )
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_backend_glx.h
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+	/usr/include/va/va_glx.h
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddriverdir="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		-Ddisable_drm=false
+		-Dwith_x11=$(usex X)
+		-Dwith_glx=$(usex X)
+		-Dwith_wayland=$(usex wayland)
+		-Denable_docs=false
+		-Denable_va_messaging=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "NVIDIA GPU support" x11-libs/libva-vdpau-driver
+	optfeature "Older Intel GPU support" x11-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support" x11-libs/libva-intel-media-driver
+}