[gentoo-commits] repo/gentoo:master commit in: sys-apps/flatpak/

["Zac Medico" <zmedico@gentoo.org>]

commit:     5cabc6cae6d34c64b2ff02a662ac528f4d6bd0ef
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 15 00:59:18 2022 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Tue Mar 15 00:59:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5cabc6ca

sys-apps/flatpak: add 1.13.2

Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 sys-apps/flatpak/Manifest              |   1 +
 sys-apps/flatpak/flatpak-1.13.2.ebuild | 105 +++++++++++++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index 03ad0f2efab1..9a1e777596c0 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,3 +1,4 @@
 DIST flatpak-1.12.3.tar.xz 1555340 BLAKE2B 512b3f6abfb06d242aedad2c27c9870750254a9d0a3769999739f8885bbf1740b649e2a41f2c079532b049fcce8b58529572ea35e930437ed6b62194a73bcbb6 SHA512 2f39665457b4c3b99e32ebc88cf5b70202dba6118887617d3d7faa20f688f3f3fc14e343b70c0d11eb15ee743a68d07078e6cda14fd91aa10ca375797cfc95bc
 DIST flatpak-1.12.7.tar.xz 1562920 BLAKE2B e0bd3fcf8e0bc329c237ba409f82d6bfad1734101068966c11f03c9e45302680f590162b04e2314b5ed93324e61b4c06c33496dba7ba59778c885f50dd00d9db SHA512 425f9d330c649de1079f3286cb6ad8cf7b6e5838921effa4fd6f51020b9bf7991ded9071566ec7032b9868ef3f7e14d1fb7c2be96f903e3af23a075592b78f50
 DIST flatpak-1.13.1.tar.xz 1626048 BLAKE2B 6dd02bd531a6d10d97ac94d744e7afc7c6a319fe576cd6e3ff882b41320f7ede5cf0d6d92dcf4287b19ae7d3e5ce6afeebd1ea0e517e566f5b218e05bdb2bc10 SHA512 7e0be34535d6e80a1d59bfc937b9a89c3b46acbbddd6a04583c4874a50539978bb493b5c08b083a5697615a3281346bf1770b681fbc27be682caf54ffdca937a
+DIST flatpak-1.13.2.tar.xz 1626616 BLAKE2B a896c1ef5166be9085c7b66bde3df510e4d592f920795706c7d0b68f717ccfd0694b306797a862d3db35c71ced5dcdb71438119d95ff5455b4b6a6b6adfa0d0e SHA512 d7e1d0a9965332220f829caa5724d7547280db10f7428b4e9add87152da1d7dad97edcde85668501d5a50e6a7c1031bfd15e8f4cbc7196e1c0f7cc3d2e333fe1

diff --git a/sys-apps/flatpak/flatpak-1.13.2.ebuild b/sys-apps/flatpak/flatpak-1.13.2.ebuild
new file mode 100644
index 000000000000..63cc95837935
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.13.2.ebuild
@@ -0,0 +1,105 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd X"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-0.12:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	X? (
+		x11-apps/xauth
+		x11-libs/libXau:=
+	)
+	x11-libs/gdk-pixbuf:2=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable X xauth)
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}