[gentoo-commits] repo/gentoo:master commit in: media-libs/libaacs/

["Sam James" <sam@gentoo.org>]

commit:     889c7b074fcde5dbca6eb8c68b4a57d24100fd26
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 14 18:59:12 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Mar 14 18:59:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=889c7b07

media-libs/libaacs: add 0.11.1-r1 with out-of-source build

We have to include a workaround for an automake bug though.

Bug: https://debbugs.gnu.org/cgi/bugreport.cgi?bug=54390
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/libaacs/libaacs-0.11.1-r1.ebuild | 40 +++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/media-libs/libaacs/libaacs-0.11.1-r1.ebuild b/media-libs/libaacs/libaacs-0.11.1-r1.ebuild
new file mode 100644
index 000000000000..3e7993af6438
--- /dev/null
+++ b/media-libs/libaacs/libaacs-0.11.1-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="Open implementation of the Advanced Access Content System (AACS) specification"
+HOMEPAGE="https://www.videolan.org/developers/libaacs.html"
+SRC_URI="https://downloads.videolan.org/pub/videolan/libaacs/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND=">=dev-libs/libgcrypt-1.5.3:0=[${MULTILIB_USEDEP}]
+	>=dev-libs/libgpg-error-1.12[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/flex
+	virtual/yacc"
+
+DOCS=( ChangeLog KEYDB.cfg README.md )
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-optimizations
+		--enable-shared
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+
+	# Workaround automake bug: https://debbugs.gnu.org/cgi/bugreport.cgi?bug=54390
+	mkdir -p "${BUILD_DIR}"/src/file || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	find "${ED}" -type f -name "*.la" -delete || die
+}