[gentoo-commits] repo/gentoo:master commit in: dev-ruby/net-ssh/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     4034fdecff0146aa067a3c0943a0863f937db0df
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 13 08:25:32 2022 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Mon Mar 14 06:33:57 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4034fdec

dev-ruby/net-ssh: add ruby30; EAPI 8

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/net-ssh/net-ssh-6.1.0-r2.ebuild | 45 ++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-ruby/net-ssh/net-ssh-6.1.0-r2.ebuild b/dev-ruby/net-ssh/net-ssh-6.1.0-r2.ebuild
new file mode 100644
index 000000000000..db9f40f2bf0e
--- /dev/null
+++ b/dev-ruby/net-ssh/net-ssh-6.1.0-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.md THANKS.txt"
+RUBY_FAKEGEM_EXTRAINSTALL="support"
+
+RUBY_FAKEGEM_GEMSPEC="net-ssh.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Non-interactive SSH processing in pure Ruby"
+HOMEPAGE="https://github.com/net-ssh/net-ssh"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> net-ssh-git-${PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="ed25519 test"
+RESTRICT="!test? ( test )"
+
+ruby_add_rdepend "virtual/ruby-ssl ed25519? ( >=dev-ruby/ed25519-1.2:1 dev-ruby/x25519 dev-ruby/bcrypt_pbkdf:1 )"
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 >=dev-ruby/mocha-0.13 )"
+
+all_ruby_prepare() {
+	# Avoid bundler dependency
+	sed -i -e '/\(bundler\|:release\)/ s:^:#:' Rakefile || die
+
+	sed -e "s:require_relative ':require './:" \
+		-e 's/git ls-files -z/find -print0/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+src_test() {
+	# prevent tests from trying to connect to ssh-agent socket and failing
+	unset SSH_AUTH_SOCK
+	if ! use ed25519; then
+		export NET_SSH_NO_ED25519=true
+	fi
+	ruby-ng_src_test
+}