[gentoo-commits] repo/gentoo:master commit in: dev-libs/gmime/

["Matt Turner" <mattst88@gentoo.org>]

commit:     35118bc6ceed83006aedb89114f19625f29e7521
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 11 19:51:43 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar 11 19:58:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=35118bc6

dev-libs/gmime: Version bump to 3.2.9

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/gmime/Manifest           |  1 +
 dev-libs/gmime/gmime-3.2.9.ebuild | 69 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-libs/gmime/Manifest b/dev-libs/gmime/Manifest
index d31b5244897a..8f94c1ffc64e 100644
--- a/dev-libs/gmime/Manifest
+++ b/dev-libs/gmime/Manifest
@@ -1,2 +1,3 @@
 DIST gmime-2.6.23.tar.xz 5216588 BLAKE2B e173a7dbd418663ebbc55b856359bf9286c3791827f9b7f89da48dd7c3609e77312546f9489c08d34a7dcaeb78659789809d5fafc1323cbae9b9f1c4a316c659 SHA512 2ff6718b7a555cd5b34848399f29c7d0aa5a15e1f3cb46e9258c499e874191ee00f41b737386805d3000bad34367d174a25c45d38ba90cba7902400e733afa14
 DIST gmime-3.2.7.tar.xz 2227048 BLAKE2B 7fba57640038f34bd45ecba1067b6db131705310b62a74da1fa3d575993bbc6cc1dce4e3d219dd42033775e0a90f2b2acc86b1094f96f03a7532eae1b69e63ae SHA512 2c8fecd6eb74c9e956c419ce111bef6280916ea3756a534b6b800a273f0fff260717cda7fefd4bd4c6ddb27973112ec6e73fa971fa74bb9aa04cfe587d45f10b
+DIST gmime-3.2.9.tar.xz 2230284 BLAKE2B b6dd81adf939fed8fee70880e2c3f907d9eb8fb33efb90c78d6e6c93754e310f44a1affa8c59ac980805be42bbd5f61353633ac071dfa8fd89b65f2f23cbda24 SHA512 00b92ff5e2001644bfac50d1736203dd478c3a44c8f325a216105c5b354540807df9a6025bd0313d1e60793d8388ed4f5ff72685e116e3f36e6ca8c6b326a19b

diff --git a/dev-libs/gmime/gmime-3.2.9.ebuild b/dev-libs/gmime/gmime-3.2.9.ebuild
new file mode 100644
index 000000000000..ccc807d2d80a
--- /dev/null
+++ b/dev-libs/gmime/gmime-3.2.9.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic gnome2 vala
+
+DESCRIPTION="A C/C++ MIME creation and parser library with support for S/MIME, PGP, and Unix mbox spools"
+HOMEPAGE="https://github.com/jstedfast/gmime http://spruce.sourceforge.net/gmime/"
+SRC_URI="https://github.com/jstedfast/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+SLOT="3.0"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+IUSE="crypt doc idn test +vala"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	sys-libs/zlib
+	crypt? ( >=app-crypt/gpgme-1.8.0:= )
+	idn? ( net-dns/libidn2:= )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/libiconv
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	test? ( app-crypt/gnupg )
+"
+# gnupg is needed for tests if --enable-cryptography is enabled, which we do unconditionally
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_setup
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]]; then
+		# bug #???, why not use --with-libiconv
+		append-libs iconv
+	fi
+
+	gnome2_src_configure \
+		--enable-largefile \
+		$(use_enable crypt crypto) \
+		$(use_enable vala) \
+		$(use_with idn libidn) \
+		$(usex doc "" DB2HTML=)
+}
+
+src_compile() {
+	gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc -r docs/tutorial/html/
+	fi
+}