[gentoo-commits] repo/gentoo:master commit in: dev-python/dulwich/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     1eec2b8971f329d9c0ad5aebb2ee3ecd74d7e223
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Mar  9 19:17:18 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Mar  9 20:06:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1eec2b89

dev-python/dulwich: add 0.20.33

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/dulwich/Manifest               |  1 +
 dev-python/dulwich/dulwich-0.20.33.ebuild | 56 +++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-python/dulwich/Manifest b/dev-python/dulwich/Manifest
index 238d29ed6426..495a2ed219a7 100644
--- a/dev-python/dulwich/Manifest
+++ b/dev-python/dulwich/Manifest
@@ -1 +1,2 @@
 DIST dulwich-0.20.32.tar.gz 418100 BLAKE2B 21d41a7b1e491848a11ab3e3b1b63bfbe1798b38ef331136b07609f004e780672477e91a637dd3b1ccd3b26e359461e1a16d759ac2cb98d1091fbdb1968c00a9 SHA512 9af4cb4462ab9a69bea9074aace81eeb8d33087f2c53e64145991913ad132e076b62f7958551729c758cd6eeae029a278723872771ef36b046331c85ebf2fcf4
+DIST dulwich-0.20.33.tar.gz 419863 BLAKE2B 57b7a05f7a23745ba63e2faba9cd3772637a61cf9f2077eaf7ec799f5e3d25de7245aabbebf22cb58f5cb45318b653335251fc46b136b108770aaa6c2b09e099 SHA512 f2d0f8875dc4cd4ac4629f2884a5e68938d14218ef96a19ce322559a16eb64cdee92ed0bc07790e9d527a20fdcd29f6fe1f95479d0055cdab88f509bc318368c

diff --git a/dev-python/dulwich/dulwich-0.20.33.ebuild b/dev-python/dulwich/dulwich-0.20.33.ebuild
new file mode 100644
index 000000000000..db9d32133a7a
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.20.33.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="
+	https://github.com/dulwich/dulwich/
+	https://pypi.org/project/dulwich/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		!hppa? ( !ia64? (
+			dev-python/gevent[${PYTHON_USEDEP}]
+			dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		) )
+		app-crypt/gpgme[python,${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/fastimport[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	# remove interference from the tests that do stuff like user.name
+	unset GIT_AUTHOR_NAME GIT_AUTHOR_EMAIL GIT_AUTHOR_DATE \
+		GIT_COMMITTER_NAME GIT_COMMITTER_EMAIL GIT_COMMITTER_DATE EMAIL
+	# Do not use make check which rebuilds the extension and uses -Werror,
+	# causing unexpected failures.
+	"${EPYTHON}" -m unittest -v dulwich.tests.test_suite ||
+		die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}