[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     b084878a793a3465e20e894d76da2f672ea11b6f
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  7 19:40:18 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon Mar  7 19:41:55 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b084878a

app-emulation/86Box: add 3.2.1

Closes: https://bugs.gentoo.org/834722
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.2.1.ebuild | 66 ++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest           |  1 +
 2 files changed, 67 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.2.1.ebuild b/app-emulation/86Box/86Box-3.2.1.ebuild
new file mode 100644
index 000000000000..8408b5693b27
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.2.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 050159bb66e2..bc9a2a378ddc 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.1.tar.gz 3733570 BLAKE2B d0753b11b040fa0bdef5d2a7c7fb9abc12f6e19c22360cc037bbd33c9274241c5941f49f509520cda2e584d989a7913aaa72b65457232c6f1d4ea1a59b013370 SHA512 9b28e23b6f3c2b9fe1a96e398c2042a4a6d3a7fcba0728033018c9cd737105bbc0f20053352f00d4ddcf8805e47152681f2151f8b03ad03305e3d27fa1adc092
+DIST 86Box-3.2.1.tar.gz 3967126 BLAKE2B 0979fc9e87da17f452022a4a1484da72eb0091835c4d7ed225e1e70940e5f7399b7b7cb22816419dbfd040a72ec2a6e50ae0eddc81cad6ef75974f4d511f9f3b SHA512 d725b9c2d2ada47e4492dd09c79af15010a03b174cf99705cf7ffbd4de39aa3a745bf5ab41e4f173e89f4c8d9c130e7540014a1824ff34bb88e634d8dc7860eb